Conditional RegExp (Allgemeines zu Perl)

[thread]14707[/thread]

Conditional RegExp

Leser: 21

Articles: hide open all | hide show old branches

+9 replies

Gast PHilbs

2010-02-20 20:44

Hallo,

ich verzweifle gerade an einem regulären ausdruck.

Folgende Texte sollen gematcht werden:

Code (perl): (dl )

1
2

my $blub = "hund:bello,12,w";
my $blab = "katze:mini,m";

der text vor dem Doppelpunkt gibt das Tier an. Hier kann nur "hund" oder "katze" stehen. Zwischen Doppelpunkt und erstem Komma steht der Name des Tieres.
Nun kommt das spannende: Wenn das Tier vom Typ "hund" ist, soll hier auch das gewicht stehen. Aber nur dann, wenn es eine Katze ist, interessiert das Gewicht nicht und es folgt gleich das Geschlecht (m|w).

Bisher sieht mein Ausdruck so aus:

Code (perl): (dl )

my $pattern = qr/^(?<t>hund|katze):(?<n>[^,]),(?<g>\d+),(?<s>m|w)$/;

t = typ
n = name
g = gewicht
s = geschlecht

Aber wie bringe ich nun die Bedingung mit in den Ausdruck?

Ich hatte dann sowas ausprobiert, was (nach der u.g. Lektüre) natürlich nicht geklappt hat:

Code (perl): (dl )

my $pattern = qr/^(?<t>hund|katze):(?<n>[^,])?(<t>=hund,(?<g>\d+)),(?<s>m|w)$/;

Ich habe mir bereits den Abschnitt http://perldoc.perl.org/perlretut.html#Conditional-expressions durchgelesen, aber ich verstehs nicht, das Beispiel ist mir dort zu kompliziert...

Kann mir jemand dabei helfen?

Gruß

PHilbs

+2 replies

murphy

2010-02-20 22:08

User since
2004-07-19
1776 Artikel
HausmeisterIn

Die Bedingungskonstrukte der Form (?(...)...|...) in einem regulären Ausdruck erlauben standardmäßig nur eine Überprüfung ob ein Subausdruck gepasst hat, nicht auf was er gepasst hat.

Du könntest also zum Beispiel die zulässigen Tiertypen in mehrere Subausdrücke verpacken und dann testen welcher gepasst hat: ^(?:(?<h>hund)|(?<k>katze))...(?(<h>)...|...)...

Wenn Du unbedingt willst, kannst Du auch Code in einen regulären Ausdruck einbetten: ^(?<t>hund|katze)...(?(?{$+{t} eq 'hund'})...|...)... — das ist aber nicht nur recht hässlich und unleserlich, sondern auch explizit in der Dokumentation als experimentell und instabil vermerkt.

Schließlich könnte man gerade in diesem Beispiel auch einfach zweimal splitten und mit gewöhnlichen Abfragen arbeiten:

Code (perl): (dl )

my ($kind, $info) = split /:/, ..., 2;

my ($name, $weight, $gender);
if ($kind eq 'hund') {
  ($name, $weight, $gender) = split /,/, $info, 3;
}
else {
  ($name, $gender) = split /,/, $info, 2;
}

When C++ is your hammer, every problem looks like your thumb.

Gast PHilbs

2010-02-20 22:49

Hallo murphy,

danke für deine Antwort. Ich habe es so wie vorgeschlagen gelöst, indem ich für die einzelnen Tiere Subausdrücke erstellt habe:

Code (perl): (dl )

#!/usr/bin/perl

use strict;
use warnings;

my $pattern = qr/^((?<k>katze)|(?<h>hund)):(?<n>[^,]+),(?(<h>)(?<g>\d+),)(?<x>w|m)/;

blub("hund:waldi,23,m");
blub("katze:rosa,w");

sub blub {
    my $string = shift;
    print "-"x20;
    print "\nString:\t\t$string\n";
    if ($string =~ $pattern) {
        print "Tier:\t\t";
        if (defined($+{k})) {
            print "$+{k}\n";
        } elsif (defined($+{h})) {
            print "$+{h}\n";
        }
        print "Name:\t\t$+{n}\n" if (defined($+{n}));
        print "Gewicht:\t$+{g}kg\n" if (defined($+{g}));
        print "Geschlecht:\t$+{x}\n" if (defined($+{x}));
    } else {
        print "no matches...\n";
    }
}

Ich bekomme folgende Ausgabe und denke somit, dass nun alles so klappt, wie es soll:

Code: (dl )

$ ./test.pl
--------------------
String:         hund:waldi,23,m
Tier:           hund
Name:           waldi
Gewicht:        23kg
Geschlecht:     m
--------------------
String:         katze:rosa,w
Tier:           katze
Name:           rosa
Geschlecht:     w

+3 replies
vifo

2010-02-20 22:20
User since
2010-01-25
11 Artikel
BenutzerIn
Hallo,

wenn Du unbedingt conditional expressions verwenden möchtest, ist das hier eine Lösungsmöglichkeit;
Code: (dl )

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21

#!/usr/bin/env perl use strict; use warnings; use Data::Dumper; my $blub = "hund:bello,12,w"; my $blab = "katze:mini,m"; my $pattern = qr{ ^(?:(?<t>hund)|(?<t>katze)) # hund oder katze, zusätzlich in \1 und \2 capturen \: # trenner (?<n>[^\,]+) # name \, # trenner (?(1) (?<g>\d+) # gewicht nur wenn \1 gematcht hat (e.g. hund) \, # trenner ) (?<s>m|w) # geschlecht $ }x;
Ausgabe:
Code: (dl )

1 2 3 4 5 6 7 8 9 10 11

$VAR1 = { 'n' => 'bello', 'g' => '12', 's' => 'w', 't' => 'hund' }; $VAR1 = { 'n' => 'mini', 's' => 'm', 't' => 'katze' };
Bei den conditional expressions kannst Du als condition einen bereits gematchten Ausdruck verwenden. Allerdings kann man hier nur feststellen, OB der Ausdruck gematcht hat, nicht dessen Inhalt (das geht wiederum mit code evaluation expressions, siehe http://perldoc.perl.org/perlretut.html#A-bit-of-magic:-executing-Perl-code-in-a-regular-expression, aber das wird als experimentell eingestuft).

Also capturen wir zusätzlich entweder "hund" oder "katze" in $1 bzw. $2 und prüfen hierauf.

Eine weitere Alternative wäre natürlich, die Strings so umzustellen, dass das Gewicht als letztes Element steht (dann würde auch einfaches split reichen).

Grüße
vifo

Edit: siehe gerade, Murphy war mit der Lösung ein bisschen schneller, aber doppelt hält besser :)
Last edited: 2010-02-20 22:22:15 +0100 (CET)
- +2 replies
- Gast PHilbs
  
  2010-02-20 22:51
  
  Hallo vifo,
  
  danke für deine Antwort, ich glaube, ich habs nun gleich gelöst, wie du oder?
  
  Gruß
  PHilbs
  - vifo
    
    2010-02-21 00:28
    
    User since
    2010-01-25
    11 Artikel
    BenutzerIn
    
    Guest PHilbs
    Hallo vifo,
    
    danke für deine Antwort, ich glaube, ich habs nun gleich gelöst, wie du oder?
    
    Gruß
    PHilbs
    
    Immer gern - der Ansatz von murphy (den Du jetzt umgesetzt hast) ist, dass beim Matchen das Capture <h> bei einem Hund bzw. <k> bei einer Katze erstellt wird (mit Inhalt "hund" respektive "katze"). Gewicht ist dann durch die Logik vorhanden, wenn das passende Capture existiert.
    
    Bei mir ist keine Unterscheidung vorhanden, es wird also die Tierart an sich in <t> gecaptured (gelöst im Match durch ein zusätzliches numerisches Capture).
    
    Grüße
    vifo
    Last edited: 2010-02-21 00:31:15 +0100 (CET)

topeg

2010-02-20 22:54

User since
2006-07-10
2611 Artikel
BenutzerIn

user image

So kann man das auch machen:

Code (perl): (dl )

#!/usr/bin/perl

use strict;
use warnings;
use Data::Dumper;

my @list=(
  'hund:bello,12,w',
  'katze:mini,m',
  'hund:lessi,8,m',
  'katze:kassandra,w',
);

for my $line (@list)
{
  $line=~/^(?<t>katze|hund):(?<n>[^,]+),(?:(?<g>\d+),)?(?<s>w|m)$/;
  $line={%+};
}

print Dumper(\@list);

das Funktioniert, weil "\d+," an der Stelle im String einmalig ist, und es zu keiner Verwechselung beim Match kommen kann.
Last edited: 2010-02-20 22:56:06 +0100 (CET)

+2 replies

sid burn

2010-02-20 23:31

User since
2006-03-29
1520 Artikel
BenutzerIn

user image

Ich würde es insgesamt so lösen.

Code (perl): (dl )

#!/usr/bin/env perl
# Core Modules
use strict;
use warnings;
use 5.010;
use utf8;
use open ':encoding(UTF-8)';
use open ':std';
use Carp;
use Try::Tiny;
use Data::Dumper;

{
    my $name   = qr/(?<n> [^,]++ )/xms;
    my $weight = qr/(?<g> \d++   )/xms;
    my $sex    = qr/(?<s> m|w    )/xms;

    my %types = (
        hund  => qr/\A (?<t> hund )  : $name , $weight , $sex \z/xms,
        katze => qr/\A (?<t> katze ) : $name , $sex \z/xms,
    );
    
    sub get_data {
        my ( $string ) = @_;
       
        # read type
        my $type;
        if ( $string =~ m/\A ([^:]++) : /xms ) {
            $type = $1;
        }
        else {
            croak "String [$string] is probably invalid";
        }
        
        # get data from string
        if ( !exists $types{$type} ) {
            croak "Don't knew what to do with type [$type].";
        }
        
        # return data
        $string =~ $types{$type};
        return { %+ };
    }
}

my @animals = (
    "hund:bello,12,w",
    "katze:mini,m",
    "maus:Mickey,12,w",
    "muahahahaha",
);

for my $animal ( @animals ) {
    try {
        my $data = get_data($animal);
        print Dumper($data);
    }
    catch {
        warn $_;
    };
}

Ausgabe:

Code: (dl )

$VAR1 = {
          'n' => 'bello',
          'g' => '12',
          's' => 'w',
          't' => 'hund'
        };
$VAR1 = {
          'n' => 'mini',
          's' => 'm',
          't' => 'katze'
        };
Don't knew what to do with type [maus]. at ./match.pl line 60
String [muahahahaha] is probably invalid at ./match.pl line 60

Mit der Lösung ist es auch leicht erweiterbar. Möchtest du z.B. den Maus Typ unterstützen kannst du einfach folgende Zeile im hash %types hinzufügen.

Code (perl): (dl )

maus  => qr/\A (?<t> maus )  : $name , $weight, $sex \z/xms,

Einzige Bedingung ist das der String immer mit einem Typ anfängt der bis zum ersten Doppelpunkt geht.

Nicht mehr aktiv. Bei Kontakt: ICQ: 404181669 E-Mail: perl@david-raab.de

betterworld

2010-02-21 11:57

User since
2003-08-21
2614 Artikel
ModeratorIn

user image

Ich haette es jetzt auch so gemacht, dass ich einfach zwei regulaere Ausdruecke hinschreibe: Einen fuer hund und einen fuer katze. Man kann sie dann auch mit "|" einfach verbinden:

Code (perl): (dl )

use strict;
use warnings;
use Data::Dumper;


my $blub = "hund:bello,12,w";
my $blab = "katze:mini,m";

for ($blub, $blab) {
    if (/^ (?<t>hund)  : (?<n>[^,]*) , (?<g>\d+) , (?<s>m|w)  $ |
         ^ (?<t>katze) : (?<n>[^,]*) ,             (?<s>m|w)  $  /x) {

         print Dumper \%+;
    }
}

Ausgabe:

Code: (dl )

$VAR1 = {
          'n' => 'bello',
          'g' => '12',
          's' => 'w',
          't' => 'hund'
        };
$VAR1 = {
          'n' => 'mini',
          's' => 'm',
          't' => 'katze'
        };

Lieblingsmodule: CPAN:

IPC::System::Simple, CPAN:

Path::Class

View all threads created 2010-02-20 20:44.