RegEx für "ip addr show" (gelöst) (Netzwerkprogrammierung und Netzwerke mit Perl)

[thread]21171[/thread]

RegEx für "ip addr show" [gelöst]

Tags: perl5 Ähnliche Threads

Leser: 10

Articles: hide open all | hide show old branches

+15 replies

cbxk1xg

2021-02-23 16:07

User since
2003-10-20
496 Artikel
BenutzerIn
[default_avatar]

Hi!

Ich habe mir eine RegEx für "ip addr show" geschrieben um alle für mich relevanten Teile zu erkennen. Ich würde nun gerne die Backreferences strukturiert in einen Hash packen. Ich stehe aber irgendwie auf dem Schlauch.

Code: (dl )

ip addr show

Code: (dl )

1: lo: <LOOPBACK,UP,LOWER_UP> mtu 65536 qdisc noqueue state UNKNOWN group default qlen 1000
    link/loopback 00:00:00:00:00:00 brd 00:00:00:00:00:00
    inet 127.0.0.1/8 scope host lo
       valid_lft forever preferred_lft forever
    inet6 ::1/128 scope host
       valid_lft forever preferred_lft forever
2: eth0: <NO-CARRIER,BROADCAST,MULTICAST,UP> mtu 1500 qdisc pfifo_fast state DOWN group default qlen 1000
    link/ether xx:xx:eb:xx:xx:xx brd ff:ff:ff:ff:ff:ff
3: wlan0: <BROADCAST,MULTICAST,UP,LOWER_UP> mtu 1500 qdisc pfifo_fast state UP group default qlen 1000
    link/ether xx:xx:xx:xx:xx:xx brd ff:ff:ff:ff:ff:ff
    inet 192.168.178.22/24 brd 192.168.178.255 scope global dynamic noprefixroute wlan0
       valid_lft 861425sec preferred_lft 753425sec
    inet6 ffff::ffff:ffff:ffff:ffff/64 scope link
       valid_lft forever preferred_lft forever

Code (perl): (dl )

(\d{1,2}\: (.+)\: \<(.+)\>.*mtu (\d+).*state (UP|DOWN|UNKNOWN).*\n.*|\n.*inet (\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})\/\d{1,2})

Link zum online RegEx-Editor mit meinem code: https://regex101.com/r/7lcsib/3/

Gast styxcc-gast

2021-02-23 17:46
Sowas vllt: (ungestestet)
Code: (dl )

1 2 3

%interfaces= ( $2 => {link => $1, abilities => $3, mtu => $4, state => $5 } );
Für abilities fällt mir gerade nichts gescheites ein..
Last edited: 2021-02-23 19:23:40 +0100 (CET)
+7 replies
styx-cc

2021-02-23 18:59
User since
2006-05-20
533 Artikel
BenutzerIn
ich schreibs noch mal, vllt so: (ungetestet)
Code: (dl )

1 2 3

%interfaces= ( $2 => {link => $1, abilities => $3, mtu => $4, state => $5 } );
Für abilities fällt mir gerade nichts gescheites ein..

beste grüße
Pörl.
- +3 replies
- cbxk1xg
  
  2021-02-23 19:56
  User since
  2003-10-20
  496 Artikel
  BenutzerIn
  Vielen dank. Das hilft mir ein wenig weiter.
  
  Allerdings ist mein größtes Problem, dass ich nicht verstehe, wie ich das in einer Schleife für alle drei oder möglicherweise mehr Interfaces herausbekomme. Denn die RegEx matched ja mehrfach.
  
  Momentan frage ich das so ab:
  
  Code (perl): (dl )
  
  1 2 3 4 5 6 7 8 9
  
  #!/usr/bin/perl use strict; use warnings; my $netStats = ""; $netStats = `ip addr show`; # Ich hatte erst überlegt das Ergebnis aufzuteilen. Aber auch das funktioniert leider nicht. Und ich finde es un-elegant. my @networksDevices = split (m/(\d{1,2}\: .+\n(\s{3,}.*\n*)+)/i, $netStats);
  - haj
    
    2021-02-23 21:13
    
    User since
    2015-01-07
    555 Artikel
    BenutzerIn
    
    Es gibt da schon mehrere Möglicheiten. Ich finde es gar nicht mal so unleserlich, mit dem split anzufangen. Dann hast Du es nämlich einfacher, das "Ende" eines Eintrags zu erkennen und zum Beispiel darauf zu reagieren, dass eth0 keine Internet-Adresse hat.
    
    Zudem sind PXRE-Ausdrücke mit etwas Vorsicht zu genießen. Perl kann mehr, insbesondere reguläre Ausdrücke mit /x richtig lesbar zu machen.
    
    Ich baue gerade einen Vorschlag, das dauert noch ein bisschen... ich poste nix ungetestetes.
  - haj
    
    2021-02-23 22:44
    User since
    2015-01-07
    555 Artikel
    BenutzerIn
    
    Der Linuxer hat's ja schon gelöst... drum nur eine kleine Ergänzung zu "das Ergebnis aufteilen":
    
    Wenn man den Input nicht zeilenweise geliefert bekommt, dann geht das Zerlegen in die einzelnen Interface-Beschreibungen recht kompakt:
    
    Code (perl): (dl )
    
    1 2
    
    my $netStats = `ip addr show`; my @interfaces = split /\n(?=\s*\d+:\s*)/,$netStats;
    
    Die Regex verwendet eine "Lookahead"-Klammer (?=regex): Die schaut nach, was kommt, nimmt es aber nicht weg. Hier schaue ich nach dem Anfang einer Interface-Beschreibung. Das \n davor sorgt dafür, dass die Regex nur zwischen den Elementen zuschlägt.
    
    Der Rest geht dann genau wie beim Linuxer, nur dass die Schleife über @interfaces und nicht über @lines läuft - und deswegen das if um den ersten regulären Ausdruck nicht gebraucht wird.
- +3 replies
- haj
  
  2021-02-23 20:01
  
  User since
  2015-01-07
  555 Artikel
  BenutzerIn
  
  Damit bekommst Du ein interface in den Hash, aber nicht alle :)
  - +2 replies
  - cbxk1xg
    
    2021-02-23 20:10
    
    User since
    2003-10-20
    496 Artikel
    BenutzerIn
    
    2021-02-23T19:01:36 haj
    Damit bekommst Du ein interface in den Hash, aber nicht alle :)
    
    Genau das meine ich. Ich stelle mich gerade zu dusselig an alle matches aus der RegEx in einen Hash oder in ein mehrdimensioniales Array zu packen.
    - styx-cc
      
      2021-02-23 20:34
      
      User since
      2006-05-20
      533 Artikel
      BenutzerIn
      
      Ganz übersehen/unbedacht gelassen...
      
      Als Ansatz, ist aber ncoh ein kleiner Fehler drin..
      
      Code (perl): (dl )
      
      1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29
      
      #!/usr/bin/perl use strict; use warnings; use Data::Dumper; my $str = << "EOM"; 1: lo: <LOOPBACK,UP,LOWER_UP> mtu 65536 qdisc noqueue state UNKNOWN group default qlen 1000 link/loopback 00:00:00:00:00:00 brd 00:00:00:00:00:00 inet 127.0.0.1/8 scope host lo valid_lft forever preferred_lft forever inet6 ::1/128 scope host valid_lft forever preferred_lft forever 2: eth0: <NO-CARRIER,BROADCAST,MULTICAST,UP> mtu 1500 qdisc pfifo_fast state DOWN group default qlen 1000 link/ether xx:xx:eb:xx:xx:xx brd ff:ff:ff:ff:ff:ff 3: wlan0: <BROADCAST,MULTICAST,UP,LOWER_UP> mtu 1500 qdisc pfifo_fast state UP group default qlen 1000 link/ether xx:xx:xx:xx:xx:xx brd ff:ff:ff:ff:ff:ff inet 192.168.178.22/24 brd 192.168.178.255 scope global dynamic noprefixroute wlan0 valid_lft 861425sec preferred_lft 753425sec inet6 ffff::ffff:ffff:ffff:ffff/64 scope link valid_lft forever preferred_lft forever EOM my %interfaces= (); while ($str =~ /(\d{1,2}\: (.+)\: \<(.+)\>.*mtu (\d+).*state (UP|DOWN|UNKNOWN).*\n.*|\n.*inet (\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})\/\d{1,2})/g) { $interfaces{$2} = {link => $1, abilities => $3, mtu => $4, state => $5 }; } print Dumper %interfaces;
      
      Pörl.
+4 replies

Linuxer

2021-02-23 20:26

User since
2006-01-27
3890 Artikel
HausmeisterIn

user image

Hi,

ohne große weitere Optimierung, hier ein Ansatz:

Öffne eine Pipe zum Kommando und lese zeilenweise aus der Pipe.
Dann kannst Du zeilenweise die Werte der einzelnen Interfaces auslesen und abspeichern.

Einfaches Beispiel unter Verwendung Deiner Regex:

Code (perl): (dl )

#! /usr/bin/env perl
use strict;
use warnings;
use Data::Dumper;

my $cmd = "ip addr show";

my %interface;

open my $pipe, '-|', $cmd or die "(E) could not execute: $cmd: $!\n";
while ( my $line = <$pipe> ) {

        if ( $line =~ m/(\d{1,2}\: (.+)\: \<(.+)\>.*mtu (\d+).*state (UP|DOWN|UNKNOWN).*\n.*|\n.*inet (\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})\/\d{1,2})/ ) {

                $interface{$2}->{link} = $1;
                $interface{$2}->{abilities} = $3;
                $interface{$2}->{mtu} = $4;
                $interface{$2}->{state} = $5;
        }

}

close $pipe;

warn Dumper \%interface;

Edit:

Ich habe meine Version nochmal überarbeitet:

Das setzt auf weniger komplexe Regex:

Code (perl): (dl )

#! /usr/bin/env perl
use strict;
use warnings;
use Data::Dumper;

my $cmd = "ip addr show";

my %interface;

open my $pipe, '-|', $cmd or die "(E) could not execute: $cmd: $!\n";

my $int;
while ( my $line = <$pipe> ) {

        if ( $line =~ m/^\d+:\s+([^:]+): <([^>]+)>/ ) {
                $int = $1;
                $interface{$int}->{abilities} = $2;
        }

        while ( $line =~ m/(mtu|state|inet6?) (\S+)/g ) {
                $interface{$int}->{$1} = $2;
        }
}

warn Dumper \%interface;

close $pipe;

Last edited: 2021-02-23 20:50:54 +0100 (CET)

meine Beiträge: I.d.R. alle Angaben ohne Gewähr und auf Linux abgestimmt!
Die Sprache heisst Perl, nicht PERL. - Bitte Crossposts als solche kenntlich machen!

+2 replies

cbxk1xg

2021-02-23 20:53

User since
2003-10-20
496 Artikel
BenutzerIn
[default_avatar]

Boah! Muss ich alles erst mal lesen. Vielen Dank für eure Antworten. Hab selbst gerade noch mal gebastelt.

Code (perl): (dl )

                my $netStats = "";
                $netStats = `ip addr show`;
                my @networksDevices = split (m/^\d{1,2}\:\s/gm, $netStats);
                shift @networksDevices;
                my %interfaces;
                for my $device (@networksDevices) {
                        #print Dumper($device);
                        if ($device =~ /^(.+)\: \<(.+)\>.*mtu (\d+).*state (UP|DOWN|UNKNOWN)/gm) {
                                %interfaces = ( $1 => {options => $2, mtu => $3, state => $4 });
                        }
                        if ($device =~ /inet (\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})\/\d{1,2}/gm) {
                                #print Dumper($1);
                        }
                        
                }
                print Dumper(%interfaces);

Leider habe ich nur ein interface im Hash %interfaces. Egal. Ich lese erst mal Eure Antworten.

cbxk1xg

2021-02-23 21:14

User since
2003-10-20
496 Artikel
BenutzerIn
[default_avatar]

Das zeilenweise Auslesen der Pipe ist der richtige Ansatz. Danke.

Ich habe das in meiner Catalyst App jetzt folgendermaßen gelöst.

Code (perl): (dl )

my $cmd = "ip addr show";
my %interfaces;

open my $pipe, '-|', $cmd or die "(E) could not execute: $cmd: $!\n";
my $device;
        while ( my $line = <$pipe> ) {

                if ( $line =~ m/^\d+:\s+([^:]+): <([^>]+)>/ ) {
                                $device = $1;
                                $interfaces{$device}->{abilities} = $2;
                }

                while ( $line =~ m/(mtu|state|qlen|brd?) (\S+)/g ) {
                                $interfaces{$device}->{$1} = $2;
                }
        }
close $pipe;

# stash für JSON view
$c->stash->{networkDevices} = \%interfaces;

Last edited: 2021-02-23 21:17:13 +0100 (CET)

cbxk1xg

2021-02-23 21:20
User since
2003-10-20
496 Artikel
BenutzerIn
Quote

Code (perl): (dl )

$line =~ m/(mtu|state|inet6?) (\S+)/g
Das ist sehr elegant. Viel besser als meine Idee!

+2 replies
Gast DaTa

2021-02-25 00:31
Bevor ich das angehe wuerde ich mir erst mal
Code: (dl )

ip --oneline addr show
anschauen :)
Last edited: 2021-02-25 08:35:01 +0100 (CET)
- Linuxer
  
  2021-02-25 10:24
  
  User since
  2006-01-27
  3890 Artikel
  HausmeisterIn
  
  Damit bleiben bei einer älteren ip Version immer noch drei Zeilen übrig für ein Interface mit IPv4 und IPv6 Adresse... (ip utility, iproute2-ss090324)
  
  Und bei einer neueren Version sind es immer noch 2 Zeilen pro Interface mit IPv4 und IPv6 Adressen, dafür fehlt dann die MAC Adresse ... (ip utility, iproute2-ss190924)
  
  Muss man halt jeweils selbst beurteilen, welche Informationen man haben will, und welche Optionen weiterhelfen.
  meine Beiträge: I.d.R. alle Angaben ohne Gewähr und auf Linux abgestimmt!
  Die Sprache heisst Perl, nicht PERL. - Bitte Crossposts als solche kenntlich machen!

View all threads created 2021-02-23 16:07.