Match Pattern über mehrere Zeilen (gelöst) (Allgemeines zu Perl)

[thread]21155[/thread]

Match Pattern über mehrere Zeilen [gelöst]

Tags: perl5 Ähnliche Threads

Leser: 10

Articles: hide open all | hide show old branches

+4 replies

bora99

2020-11-13 23:11

User since
2009-12-05
54 Artikel
BenutzerIn
[default_avatar]

Hallo,

in einem Script habe ich folgenden Vorschlag für Suche in einer Datei mit Zeilen mit 1. "(" und 1. ")"

- Die Zeichen "(" , ")" können an einer beliebigen Stelle sich befinden,
dahinter ein Pattern

Erstellung Testfile

Code: (dl )

cat > testfile <<-EOF
 ( START
zeile2
zeile3
) ENDE
zeile5
( NÄCHSTE
zeile7
zeile8
) ENDE
EOF

Ergebnis:

( START
zeile2
zeile3
) ENDE

Versucht habe ich in Script den Code

Code (perl): (dl )

if (/BEGIN PATTERN/ .. /END PATTERN/) {

aber nur mit dem Script bin ich zum Ergebnis gekommen.
Ergebnis soll gespeichert werden in einem Array.
Es funktioniert wahrscheinlich besser ? Aber soll kein One Liner sein

Code (perl): (dl )

#!/usr/bin/perl -w

my $TestFile = "testfile";
my $found1 = 0;
my $found2 = 0;
my %found_arr = ();
my $i = 0;

if( ! open( TFH, $TestFile))
  {
  print STDERR "Test File '$TestFile' kann nicht gelesen werden !\n";
  exit 1;
  }

while( $line = <TFH> )
   {
   chomp $line;
    if( ( $line =~ m/^\s*([\x28])/i ) && ( ! $found1 ) )
      {
      $found_arr[$i]=$line;
      $i++;
      $found1 ++;
      }
      if( ( $found1 ) && ( ! $found2 ) )
        {
        if( ! $found2 )
          {
          if( ( $line !~ m/^\s*([\x28])/i ) && ( $line !~ /\Q)/ ) )
            {
            $found_arr[$i]=$line;
            $i++;
            }
            else
            {
            if( $line =~ /\Q)/ )
              {
              $found2 ++;
              $found_arr[$i]=$line;
              $i++;
              }
            }
          }
        }
   }
close( TFH);

for( $i = 0; $i <= $#found_arr; $i++)
  {
  print "$found_arr[$i]\n";
  }
exit 0;

Last edited: 2020-11-13 23:12:49 +0100 (CET)

+3 replies

haj

2020-11-14 02:08

User since
2015-01-07
557 Artikel
BenutzerIn

user image

Ja, der Flip-Flop ist etwas gewöhnungsbedürftig, aber genau für solche Fälle gemacht:

Code (perl): (dl )

use 5.020;
use strict;
use warnings;

my $TestFile = "testfile";

open (my $tfh,'<',$TestFile)
    or die "Test File '$TestFile' kann nicht gelesen werden: '$!' !\n";

my @found_arr = (); # nicht %found_arr - das wäre ein Hash

while (my $line = <$tfh>) {
    chomp $line;
    push @found_arr, $line if ($line =~ /\(/ .. $line =~ /\)/);
}

# In Perl kann man eine Schleife über ein Array sehr einfach schreiben:
for my $found (@found_arr) {
    say $found;
}

Und immer dann, wenn man in einer Schleife von einem Array in ein anderes schaufelt, kommen die Perl-Funktionen map und grep sehr gelegen. Hier ist es grep:

Code (perl): (dl )

use 5.020;
use strict;
use warnings;

my $TestFile = "testfile";

open (my $tfh,'<',$TestFile)
    or die "Test File '$TestFile' kann nicht gelesen werden: '$!' !\n";

my @found_arr = grep { /\(/ .. /\)/ } <$tfh>;
chomp (@found_arr);

say for @found_arr;

Bei say habe ich ausgenützt, dass Perl $_ als Standard-Variable verwendet. Bei solchen sehr kurzen Schleifen halte ich das für sinnvoll.

+2 replies

bora99

2020-11-15 23:29

User since
2009-12-05
54 Artikel
BenutzerIn
[default_avatar]

Danke für die Flip-Flop Operatior Hinweis

Für das gewünschte Ergebnis mit Suche in einer Datei mit Zeilen mit 1. "(" und 1. ")" :

( START
zeile2
zeile3
) ENDE

habe die die 1. Variante wie folgt erweitert :

Code (perl): (dl )

#!/usr/bin/perl -w
use 5.020;
use strict;
use warnings;

my $TestFile = "testfile";

open (my $tfh,'<',$TestFile)
    or die "Test File '$TestFile' kann nicht gelesen werden: '$!' !\n";

my @found_arr = (); # nicht %found_arr - das wäre ein Hash

while (my $line = <$tfh>) {
    chomp $line;
    # push @found_arr, $line if ($line =~ /\(/ .. $line =~ /\)/);
    if ( $line =~ /\(/ .. $line =~ /\)/)
    {
       push @found_arr, $line;
       last if ( $line =~ /\)/ );
    }
}

# In Perl kann man eine Schleife über ein Array sehr einfach schreiben:
for my $found (@found_arr) {
    say $found;
}

die 2. Variante mit "grep" ist dann nicht möglich ?

Beste Grüsse

haj

2020-11-16 09:23

User since
2015-01-07
557 Artikel
BenutzerIn

2020-11-15T22:29:35 bora99
die 2. Variante mit "grep" ist dann nicht möglich ?

Wenn Du nur den ersten Treffer haben willst, dann ist Deine Variante die richtige: Du kannst nach dem ersten Ende-Kriterium aufhören und brauchst gar nicht die ganze Datei zu lesen.

View all threads created 2020-11-13 23:11.