Hashkey finden (gelöst) (Allgemeines zu Perl)

[thread]18538[/thread]

Hashkey finden [gelöst]

Tags: perl5 Ähnliche Threads

Leser: 14

Articles: hide open all | hide show old branches

+9 replies

bianca

2013-08-24 09:00

User since
2009-09-13
7016 Artikel
BenutzerIn

user image

Guten Morgen!

Der folgende Code soll eigentlich 'barname' liefern. Es soll über den Wert von "ident" die Value von {name} zurück geben.
Warum steht stattdessen immer '2' in der Variable?
Wie wäre die Syntax richtig? Was mache ich da wieder falsch?

Code (perl): (dl )

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;

my %test = (
    sup     => [
        {
            name            => 'Fooname',
            ident           => 'foo',
        },
        {
            name            => 'barname',
            ident           => 'bar',
        },
    ],
);

my $match = map {$_->{ident} eq 'bar' ? $_->{name} : ''} @{$test{sup}};
print "'$match'\n";

10 print "Hallo"
20 goto 10

GwenDragon

2013-08-24 09:45
User since
2005-01-17
14766 Artikel
Admin1
map liefert bei Zuweisung an einen Skalar die Anzahl der Listenelemente, bei Zuweisung an ein Array eine Liste.

Schau es dir bitte mal damit an:
Code (perl): (dl )

1 2

my @match = map {$_->{ident} eq 'bar' ? $_->{name} : ''} @{$test{sup}}; print "'$_'\n" for @match;
Last edited: 2013-08-24 09:48:15 +0200 (CEST)
die Drachin Gwen

Meine Perl-Artikel · perldev – verschiedene Perl-Versionen unter Windows starten
+3 replies

GwenDragon

2013-08-24 10:16

User since
2005-01-17
14766 Artikel
Admin1

Wolltest du vielleicht nur den einen Wert verwenden? Das geht mit grep und map.

Code (perl): (dl )

my ($match) = 
  map  { $_->{name} } 
  grep { $_->{ident} eq 'bar' } 
  @{ $test{sup} };

Editiert von GwenDragon: Link zu Perldoc
Last edited: 2013-08-24 10:19:47 +0200 (CEST)

die Drachin Gwen

Meine Perl-Artikel · perldev – verschiedene Perl-Versionen unter Windows starten

+2 replies

murphy

2013-08-24 11:18

User since
2004-07-19
1776 Artikel
HausmeisterIn

Es geht alternativ auch in einem Schritt mit map, wenn man Listen zurückgibt:

Code (perl): (dl )

1
2
3

my ($match) = 
  map  { $_->{ident} eq 'bar' ? ($_->{name}) : () }
  @{ $test{sup} };

When C++ is your hammer, every problem looks like your thumb.

GwenDragon

2013-08-24 11:35

User since
2005-01-17
14766 Artikel
Admin1

Ja, die Liste gleich in map zurück geben ist effizienter (ca. 8% schneller).

Code (perl): (dl )

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;

use Benchmark qw(:all);

my %test = (
    sup     => [
        {
            name            => 'Fooname',
            ident           => 'foo',
        },
        {
            name            => 'barname',
            ident           => 'bar',
        },
    ],
);

print cmpthese(1000_000, {
        'map+grep' => sub { 
                        my ($match) = 
                        map{$_->{name}}
                        grep{$_->{ident}eq'bar'} 
                        @{$test{sup}};
                },
        'map list' => sub {
                        my ($match) = 
                        map{$_->{ident}eq'bar'?($_->{name}):()} 
                        @{$test{sup}};
                },
    });


__END__

             Rate map+grep map list
map+grep 529661/s       --      -7%
map list 572410/s       8%       --

die Drachin Gwen

Meine Perl-Artikel · perldev – verschiedene Perl-Versionen unter Windows starten

+3 replies
rosti

2013-08-24 11:38
User since
2011-03-19
3496 Artikel
BenutzerIn
map{} liefert Dir ein Array, hier schonmal ein Fehler im Kontext ;)

Wir füttern map{}'right side' mal nicht direkt mit dem Array sondern mit dem Array für die Indizies. Das sieht dann so aus:
Code (perl): (dl )

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20

package main; use strict; use warnings; my %test = ( sup => [ { name => 'Fooname', ident => 'foo', }, { name => 'bardame', ident => 'bar', }, ], ); my @match = map {$test{sup}[$_]{ident} eq 'bar' ? $test{sup}[$_]{name} : ''} (0.. scalar @{$test{sup}} - 1); print "@match \n";
Das Array mit dem Ergebnis enthält 'bardame' als sichtbares Element. Es sind jedoch zwei Elemente in @match, guckstdu:
Code (perl): (dl )

1 2 3

my @match = map {$test{sup}[$_]{ident} eq 'bar' ? $test{sup}[$_]{name} : 'KA'} (0.. scalar @{$test{sup}} - 1); print "@match \n"; # KA bardame
Last edited: 2013-08-24 11:42:01 +0200 (CEST)
- GwenDragon
  
  2013-08-24 11:59
  
  User since
  2005-01-17
  14766 Artikel
  Admin1
  
  Ist aber nur halb so schnell wie grep+map bzw. map mit Listenrückgabe.
  die Drachin Gwen
  
  Meine Perl-Artikel · perldev – verschiedene Perl-Versionen unter Windows starten
- pq
  
  2013-08-24 15:13
  
  User since
  2003-08-04
  12208 Artikel
  Admin1
  
  2013-08-24T09:38:39 rosti
  map{} liefert Dir ein Array, hier schonmal ein Fehler im Kontext ;)
  
  keine funktion in perl liefert ein array zurück.
  map liefert eine liste der ergebnisse, wenn im listenkontext aufgerufen. eine liste ist aber kein array. man kann die liste dann aber in einem array abspeichern.
  wenn im skalaren kontext aufgerufen, liefert es die anzahl der ergebnisse.
  Always code as if the guy who ends up maintaining your code will be a violent psychopath who knows where you live. -- Damian Conway in "Perl Best Practices"
  lesen: Wie frage ich & perlintro brian's Leitfaden für jedes Perl-Problem
bianca

2013-08-24 16:59

User since
2009-09-13
7016 Artikel
BenutzerIn

Danke allen, hab wieder was gelernt!
10 print "Hallo"
20 goto 10

View all threads created 2013-08-24 09:00.