STDOUT in einen eigenen Puffer (gelöst) (Allgemeines zu Perl)

[thread]17996[/thread]

STDOUT in einen eigenen Puffer [gelöst]

Tags: perl5 print Buffer STDOUT Ähnliche Threads

Leser: 20

Articles: hide open all | hide show old branches

+8 replies

rosti

2012-12-16 11:20

User since
2011-03-19
3492 Artikel
BenutzerIn

Hi,

alles was print() bekommt, geht ja standardmäßig auf STDOUT. Ich suche nun eine Möglichkeit, díesen Automatismus zu umgehen, so dass eine Anweisung print(123); im Script alles in einen Buffer schreibt ohne dass der print()-Syntax geändert werden muss.

Ja, und was wir dann noch brauchen, ist eine Anweisung, mit welcher die 'gesammelten Werke' dann auf STDOUT ausgegeben werden ;)

Wie könnte sowas aussehen? Bitte mal um Hinweise,
Rosti

PS/Edit: Oh, mann, select, lange isses her ;)
Also, ich habe jetzt ein temp. Handle und verbiege STDOUT, das geht.
Gibt es evntl. noch eine andere Möglichkeit unter Verzicht auf eine temporäre Datei?

Ok, ich hab was Schönes gefunden: http://search.cpan.org/~reynolds/IO-Capture-0.05/l...

Schönen Sonntag!
Last edited: 2012-12-16 12:03:03 +0100 (CET)

+3 replies
topeg

2012-12-16 13:43
User since
2006-07-10
2611 Artikel
BenutzerIn
Benutze IO::String und Ersetze STDOUT:
Code (perl): (dl )

1 2 3 4 5 6 7 8 9 10 11

#!/usr/bin/perl use strict; use warnings; use IO::String; my $io=tie( *STDOUT, 'IO::String' ); print "test\n"; print "LINE $_\n" for(0..9); my $txt=$io->string_ref(); warn $$txt;
Das habe ich schon für alte Scripte gemacht, ist aber nicht sonderlich schnell.
- rosti
  
  2012-12-16 14:10
  
  User since
  2011-03-19
  3492 Artikel
  BenutzerIn
  
  Ohh, schön, ausgezeichnet, vielen Dank Topeg!!!!
  Es gibt ja doch ne ganze Menge. machen wir das Beste daraus ;)
  Viele Grüße,
  Rosti
- rosti
  
  2012-12-18 09:22
  
  User since
  2011-03-19
  3492 Artikel
  BenutzerIn
  
  hi Topeg, vielen Dank! IO::String ist genau das, was ich gesucht habe.
+4 replies

betterworld

2012-12-17 10:39

User since
2003-08-21
2614 Artikel
ModeratorIn

user image

Das hier fällt mir noch ein:

Code (perl): (dl )

open my $fh, '>', \my $buf or die $!;
select $fh;

print "hallo ";
print "welt";

warn "<<$buf>>";

Lieblingsmodule: CPAN:

IPC::System::Simple, CPAN:

Path::Class

+3 replies

rosti

2012-12-17 10:46

User since
2011-03-19
3492 Artikel
BenutzerIn

hi danke!

Also, irgendwie tendiere ich nun doch auch mehr zu einer temporären Datei für den Buffer, das schafft klare Verhältnisse ;)

Meine Lösung sieht seit gestern abend so aus:

Code (perl): (dl )

#!/usr/bin/perl

use strict;
use warnings;
use OutBuffer;

my $ob = OutBuffer->new(tmpdir => 'd:/tmp') or die $@;
$ob->start; # die Ähnlichkeit mit PHP ob_start ist rein zufällig

# ein paar print-Anweisungen
print 123456789, "\n", "...hau rein ...\n";
# sehnix

# hier ein paar kritische Sachen, wo eine
# Exception geworfen werden könnte
eval{ die 123};

print "Hallo???"; # und noch ein print...

# harvest
# try/catch
if($@){
        $ob = undef;
        print $@;
}
else{ $ob->out; }

--Rosti

+2 replies

payx

2012-12-17 11:43

User since
2006-05-04
564 Artikel
BenutzerIn

user image

Hallo rosti,

CPAN:

OutBuffer habe ich im CPAN nicht gefunden. Warum verwendet Du nicht CPAN:

File::Temp? Das funktioniert nach meiner Erfahrung prima (ohne statischen Pfad, mit cleanup usw.).

Grüße
payx

rosti

2012-12-17 11:54

User since
2011-03-19
3492 Artikel
BenutzerIn

2012-12-17T10:43:37 payx
Hallo rosti,

OutBuffer habe ich im CPAN nicht gefunden. Warum verwendet Du nicht File::Temp? Das funktioniert nach meiner Erfahrung prima (ohne statischen Pfad, mit cleanup usw.).

Grüße
payx

Oh, sorry, OutBuffer ist ein eigenes Modul, das verwendet File::Temp ;)

Code (perl): (dl )

package OutBuffer;

use strict;
use warnings;
use File::Temp qw(tempfile);
use Carp;

sub new{
        my $class = shift;
        my %in = (
                tmpdir => '/tmp',
        @_);
        my $self = bless{}, $class;
        return eval{
                croak "Dir '$in{tmpdir}' does'nt exists" if not -d $in{tmpdir};
                croak "No write permission to '$in{tmpdir}'" if not -w $in{tmpdir};
                ($self->{FH}, $self->{FN}) = tempfile(DIR => $in{tmpdir}) or croak "Can't create tmp FH, FN";
                $self;
        };
}

sub start{
        my $self = shift;
        select $self->{FH};
}

# from temp Handle to STDOUT
sub out{
        my $self = shift;
        seek $self->{FH}, 0,0;
        select STDOUT;
        while(read $self->{FH}, my $buffer, 1024){ print $buffer }
}

# delete tmp File
sub DESTROY{
        my $self = shift;
        close $self->{FH} if defined $self->{FH};
        unlink $self->{FN} if defined $self->{FN};
        select STDOUT;
}
1;##################################################################################################

View all threads created 2012-12-16 11:20.