Arrays aus Datei mit Loops (Allgemeines zu Perl)

[thread]17981[/thread]

Arrays aus Datei mit Loops

Tags: perl5 Ähnliche Threads

Leser: 16

Articles: hide open all | hide show old branches

+6 replies

Gast Lychness

2012-12-11 17:00

Hallo liebe Forenmitglieder.
Ich möchte gerne nach jedem Durchlauf einer while Schleife die Ergebnisse immer in ein neues Array packen und mit diesem Array den geometrischen Mittelwert berechnen.
In der Infile steht immer start, dann neue Zeilen mit jeweils einem Wert pro Zeile, dann End. Dann wieder Start dann neue Zeilen mit jeweils einem Wert pro Zeile dann End usw.

Code (perl): (dl )

 use warnings;
use strict;
use Statistics::Descriptive;

open (INFILE, '<wwertenewgene.txt') or die "Opening input file failed: $!\n";
open (OUTFILE, '>TEST.txt'); 


#my $linenumber = 0;
while (<INFILE>)
{
foreach (/start/../end/)
{
my @gene = $_;
next if /start/||/end/;
print OUTFILE "@gene";

# if (<INFILE> =~ m/final/ ){last;}
# do
# {
# print "$linenumber";$linenumber++;
# }
# until ($newgene =~m/newgene/);
}
# print OUTFILE "hallo\n";
}

#print 'Geometrischer Mittelwert: ',
#$stat->geometric_mean(), "\n";

Der Code kann noch nichts wirklich, aber vielleicht erkennt ja jemand was damit anfangen. Die Grundidee ist jedenfalls die Werte zwischen start und end jeweils in einen Array zu packen, aus dem Array den geometrischen Mittelwert bilden und diesen in eine Outfile zu printen. und dann wieder von vorn, bis die letzte Zeile erreicht ist.

Vielleicht kann ja jemand helfen oder ein paar Denkanstöße geben, vielleicht hat ja auch jemand eine idee, wie man das klüger lösen kann. Die Infile sieht in etwa so aus:

start
0.23
0.32434
0.234
1.0
end
start
0.3423
1.4
end
start
....
und irgendwann
start
1.000
0.34234
0.6754
end
final
Last edited: 2012-12-11 17:03:00 +0100 (CET)

Linuxer

2012-12-11 19:36

User since
2006-01-27
3890 Artikel
HausmeisterIn

user image

Hi,

ein möglicher Ansatz:

Code (perl): (dl )

#! /usr/bin/perl
use strict;
use warnings;
use List::Util qw( sum );

my @values;

while ( my $line = <DATA> ) {
    if ( $line =~ m{^start$} ... $line =~ m{^end$} ) {
        
        if ( $line !~ m{^(?:start|end)$} ) {
            push @values, $line;
        }
        elsif ( $line =~ m{^end$} ) {
            # einfacher Mittelwert
            my $average = sum(@values)/@values;
            print $average, "\n";

            # reset for next dataset
            @values = ();
        }

    }

}

__DATA__
start
0.23
0.32434
0.234
1.0
end
start
0.3423
1.4
end
final

meine Beiträge: I.d.R. alle Angaben ohne Gewähr und auf Linux abgestimmt!
Die Sprache heisst Perl, nicht PERL. - Bitte Crossposts als solche kenntlich machen!

+4 replies

Linuxer

2012-12-11 19:41

User since
2006-01-27
3890 Artikel
HausmeisterIn

user image

Hi nochmal,

ein anderer möglicher Ansatz:

Code (perl): (dl )

#! /usr/bin/perl
use strict;
use warnings;
use List::Util qw( sum );

my @values;

{
    # jeweils blockweise einlesen bis zum "end\n"
    local $/ = "end\n";
    while ( my $dataset = <DATA> ) {

        my @values = grep { m{^[\d.]+$} }
          split m{\n}, $dataset;

        next if !@values;

        my $average = sum(@values)/@values;
        print $average, "\n";
    }
}



__DATA__
start
0.23
0.32434
0.234
1.0
end
start
0.3423
1.4
end
final

meine Beiträge: I.d.R. alle Angaben ohne Gewähr und auf Linux abgestimmt!
Die Sprache heisst Perl, nicht PERL. - Bitte Crossposts als solche kenntlich machen!

+3 replies
Raubtier

2012-12-11 22:23
User since
2012-05-04
1075 Artikel
BenutzerIn
Nur zur Sicherheit: diese Zeilen von Linuxer solltest du ersetzen:
2012-12-11T18:41:29 Linuxer

Code (perl): (dl )

use List::Util qw( sum );

bzw.

Code (perl): (dl )

1 2

my $average = sum(@values)/@values; print $average, "\n";
durch
Code (perl): (dl )

use Statistics::Descriptive;
und
Code (perl): (dl )

1 2 3

my $stat = Statistics::Descriptive::Full->new(); $stat->add_data(@values); print "geometric_mean: ", $stat->geometric_mean(), "\n";
Aber das dürfte ja klar sein, geometrisches und arithmetisches Mittel sind ja was anderes :-)
- Gast Lychniss
  
  2012-12-12 10:27
  
  Es funktioniert wunderbar! Vielen, vielen Dank an Linuxer und an das Raubtier! :)
  Last edited: 2012-12-12 11:04:17 +0100 (CET)
- Linuxer
  
  2012-12-12 11:12
  
  User since
  2006-01-27
  3890 Artikel
  HausmeisterIn
  
  Das Auszutauschen war als Aufgabe an den Gast gedacht ;)
  meine Beiträge: I.d.R. alle Angaben ohne Gewähr und auf Linux abgestimmt!
  Die Sprache heisst Perl, nicht PERL. - Bitte Crossposts als solche kenntlich machen!

View all threads created 2012-12-11 17:00.