Auslesen von Hash-Keys und selbstaufrufende Funktion (Allgemeines zu Perl)

[thread]16732[/thread]

Auslesen von Hash-Keys und selbstaufrufende Funktion

Tags: perl5 Ähnliche Threads

Leser: 18

Articles: hide open all | hide show old branches

+4 replies

reen_sc

2011-09-15 15:21

User since
2011-09-15
2 Artikel
BenutzerIn
[default_avatar]

Hallo Leute,

da ich nicht wirklich ein Programmierer bin, ich aber etwas codingtechnisch umsetzen muss, brauche ich mal etwas Unterstützung von euch. Hintergrund ist, div. Daten per SNMP und Perl von Netzwerkdevices abzufragen. Das klappt auch schon ganz gut :-) Jetzt möchte ich aber eine Funktion schreiben, welche mir die Forwarding-Database für jedes VLAN von einem Switch abfragt. Auch das funktioniert bereits ohne Probleme, aber ich bin etwas skeptisch, wenn ich 200 SNMP Anfragen (für jedes VLAN) an das Device zur gleichen Zeit stelle (funktioniert zwar, aber irgendwann wird damit wohl schluss sein und das Device könnte abstürtzen).

Meine Überlegung ist, nur 10 oder 20 VLAN-Anfragen pro Device parallel zu stellen.

Grob gesagt sieht meine Struktur wie folgt aus. Quasi ein Hash of Hashes. Der Key im Unterhash ist immer das entsprechende VLAN (der Value ist nur als Platzhalter hier eingetragen)

Code: (dl )

%hash = ( "DEVICE_1" => { "1" => "VLAN_1",
                          "2" => "VLAN_2"},
          "DEVICE_2" => { "1" => "VLAN_1",
                          "2" => "VLAN_2",
                          ...           
                          "100" => "VLAN_100",
                        },
         );

Die Funktion die ich schreiben möchte, soll dabei immer den kompletten Hash (also alle DEVICE_x) durchlaufen und aus den Unterhashes stets nur 10 oder 20 keys holen und zwar solange, bis keine Daten mehr in den Unterhashes für jedes Device vorhanden sind.

Code: (dl )

sub BUILD_REQUESTS {
  foreach my $device (keys %hash) {
     foreach my $vlan (keys %{$hash{$device}}) {
        => durchlaufe es genau 10x
        
        => übergebe $device und $vlan an eine Subroutine,
           welche die SNMP Objekte erstellt
        
        => entferne $vlan key aus Hash, damit diese nicht wieder 
           aufgerufen werden können ???
     }
  }

  snmp_dispatcher(); => damit werden die SNMP Abfragen an die Devices   
                        durchgeführt (aus den zuvor erstellten SNMP 
                        Objekten)

  ! danach müsste nach meinem Verständis geprüft werden, ob sich noch 
    VLANs Keys in den Unterhashes befinden...richtig???

  ! wenn JA, dann müsste sich ja die komplette Funktion "sub 
    BUILD_REQUESTS" noch mal aufrufen und zwar solange, bis es nichts mehr 
    gibt!? Oder wie würde das ein Perl Profi machen? Mit Rekursion in den 
    Schleifen schon???
}

Kann man das so machen? Wenn ja, wie mache ich den Absprung aus der Schleife nach 10x durchlaufen bzw. wenn z.B. nach 5 Durchläufen keine Elemente im Hash sind? Und kann man das auch mit dem Aufruf der Funktion aus der gleichen Funktion so anstellen???

Fragen über Fragen. Hoffe ich habe es nicht zu verwirrend dargestellt ;-)

Vielen Dank im Voraus.

mfg
Reen
Last edited: 2011-09-15 15:24:22 +0200 (CEST)

+3 replies

renee

2011-09-15 16:22

User since
2003-08-04
14371 Artikel
ModeratorIn

Als Hinweis:

Code (perl): (dl )

my @var = 1 .. 38;
while ( @var ) {
   my @splice = splice @var, 0, 10;
   print "@splice\n";
}

Deine zweite for-Schleife musst Du mit so einem Konstrukt ersetzen:

Code (perl): (dl )

sub BUILD_REQUESTS {
  foreach my $device (keys %hash) {
     my @vlans = keys %{$hash{$device}};
     while ( @vlans ) {
         my @splice = splice @vlans, 0, 10;
         # mache jetzt etwas mit den 10 vlans in @splice
     }
  }
}

OTRS-Erweiterungen (http://feature-addons.de/)
Frankfurt Perlmongers (http://frankfurt.pm/)
--

Unterlagen OTRS-Workshop 2012: http://otrs.perl-services.de/workshop.html
Perl-Entwicklung: http://perl-services.de/

+2 replies

reen_sc

2011-09-16 11:18

User since
2011-09-15
2 Artikel
BenutzerIn
[default_avatar]

Hallo Renee,

das ist schon fast was ich suche, aber leider noch nich ganz das Richtige. Die Schleife zerlegt zwar den Inhalt des Hash of Hash mit der Splice Funktion in meine benötigten Teile, aber auch nacheinander und für jedes "DEVICE_x" sequentiell.

Ich suche eine Funktion, welche 10 VLANs aus DEVICE_1 nimmt, dann zu DEVICE_2 geht und da wiederrum 10 VLANs rausnimmt usw.. Erst jetzt sollen die parallelen SNMP Anfragen gestartet werden. Nachdem das Programm alle SNMP Responses zurückbekommen hat, muss die Funktion wieder prüfen, ob noch restliche VLAN's in den einzelnen DEVICES_x übrig sind, für welche die Funktion jetzt wieder nur 10 VLANs rausholt und an die SNMP Funktion übergibt.
Die Funktion muss sich mM. nach solange selbst aufrufen, bis keine VLANs mehr übrig sind. Habe nur keine Ahnung wie ich das anstellen soll, weil ich die verbleibenden VLANs an die Funktion selbst wieder übergeben müsste.

Weisst du was ich meine?

Linuxer

2011-09-16 12:10

User since
2006-01-27
3890 Artikel
HausmeisterIn

user image

Warum muss es eigentlich eine sich selbst aufrufende Funktion sein?

Lösungsvorschlag ohne Rekursion:

Code (perl): (dl )

#! /usr/bin/perl
# vim:ts=4 sw=4 sts=4 et nu fdc=3:
use strict;
use warnings;

use Data::Dumper;
$Data::Dumper::Sortkeys = 1;

# data structure: Hash of Arrays
# Device => [ list of vlan IDs ]
my %vlan = (
    device_1 => [ 1..38 ],
    device_2 => [ 1..48 ],
    device_3 => [ 1..24 ],
);

# take 10 items of each device sub hash
# process items
# redo until all sub hashs are empty

while ( 1 ) {

    my %data = ();

    for my $dev ( keys %vlan ) {
        
        # skip if no vlan IDs left for current device
        next if 0 == @{ $vlan{$dev} };

        # extract next 10 IDs of current device
        $data{$dev} = [ splice( @{$vlan{$dev}}, 0, 10 ) ];
    }

    # nothing extracted? we are finished
    last if 0 == keys %data;

    # process extracted data
    print Dumper( \%data );
}

__END__

Noch eine Variante mit anderer Schleife ...

Code (perl): (dl )

#! /usr/bin/perl
# vim:ts=4 sw=4 sts=4 et nu fdc=3:
use strict;
use warnings;

use Data::Dumper;
$Data::Dumper::Sortkeys = 1;

# data structure: Hash of Arrays
# Device => [ list of vlan IDs ]
my %vlan = (
    device_1 => [ 1..38 ],
    device_2 => [ 1..48 ],
    device_3 => [ 1..24 ],
);

# take 10 items of each device sub hash
# process items
# redo until all sub hashs are empty

my %data;
do {
    %data = ();

    for my $dev ( keys %vlan ) {
        
        # skip if no vlan IDs left for current device
        next if 0 == @{ $vlan{$dev} };

        # extract next 10 IDs of current device
        $data{$dev} = [ splice( @{$vlan{$dev}}, 0, 10 ) ];
    }

    # process extracted data
    print Dumper( \%data );
}
while ( keys %data );

__END__

Und noch eine mit eigener Subroutine und "normaler" Schleife:

Code (perl): (dl )

#! /usr/bin/perl
# vim:ts=4 sw=4 sts=4 et nu fdc=3:
use strict;
use warnings;

use Data::Dumper;
$Data::Dumper::Sortkeys = 1;

# data structure: Hash of Arrays
# Device => [ list of vlan IDs ]
my %vlan = (
    device_1 => [ 1..38 ],
    device_2 => [ 1..48 ],
    device_3 => [ 1..24 ],
);



sub fetch_data {
    my $hRef = shift;
    my %data;

    for my $dev ( keys %$hRef ) {
        # skip if no vlan IDs left for current device
        next if 0 == @{ $vlan{$dev} };

        # extract next 10 IDs of current device
        $data{$dev} = [ splice( @{$vlan{$dev}}, 0, 10 ) ];
    }

    return %data;
}


# take 10 items of each device sub hash:  via fetch_data()
# process items:  print Dumper( \%data )
# redo until all sub hashs are empty
while ( my %data = fetch_data( \%vlan ) ) {
    print Dumper( \%data );
}

__END__

edit1: $D::D::Sortkeys im Code eingefügt
edit2:weitere Variante eingefügt

Last edited: 2011-09-17 09:38:42 +0200 (CEST)

meine Beiträge: I.d.R. alle Angaben ohne Gewähr und auf Linux abgestimmt!
Die Sprache heisst Perl, nicht PERL. - Bitte Crossposts als solche kenntlich machen!

View all threads created 2011-09-15 15:21.