CSV Datei als Hash aufbauen (gelöst) (Allgemeines zu Perl)

[thread]16206[/thread]

CSV Datei als Hash aufbauen [gelöst]

Tags: perl5 CSV Ähnliche Threads

Leser: 21

Articles: hide open all | hide show old branches

+5 replies

PETER_PAN2009

2011-04-19 16:58

User since
2009-08-24
111 Artikel
BenutzerIn
[default_avatar]

Hallo zusammen!

Ich stehe wieder mal vor einem Problemchen. Ich habe eine CSV-Datei die ich durchparsen muss. Dabei sollen die Werte in eine Excel Tabelle geschrieben werden. Die Quelle für die Excel-Talle soll ein Hash sein.

Format der Datei:

Code: (dl )

1
2
3

Name,Vorname,Alter
Meyer,Peter,56
Schmidt,Andre,74

Die Datei lese ich ganz normal ein:

Code (perl): (dl )

1
2
3

open ($FH,"<", "test.csv") || die $!;
my @inhalt = <$FH>; 
close $FH;

Danach möchte ich die Werte aus der ersten Zeile als Keys in meinem Hash verwenden:

Code (perl): (dl )

my %hash = map { $inhalt[0] => 1 } @inhalt;

Jetzt kommt die foreach Schleife, inder ich die restlichen Zeilen als Values haben möchte. Und hier ist auch das Problem, wie kriege ich es hin, dass der Key "Name" die Values "Meyer" und "Schmidt" zugeweisen bekommt?

Danke und Gruß
Peter

Text::CSV

rosti

2011-04-19 17:17

User since
2011-03-19
3492 Artikel
BenutzerIn

Edit:

Sorry, vorhin war ich nicht ganz bei der Sache... also Du brauchst einen Helper, der aus der ersten Zeile heraus, die Zuordnung macht. Zum Testen habe ich die erste Zeile mal von Hand rausgenommen und den Helper erstellt. Die CSV ohne erste Zeile als DATA. Siehe Code

Code (perl): (dl )

package Names;

###########################################################################
# Rolf Rost, 14.2.2011
# Anonyme Array-Elemente bekommen Namen
###########################################################################
use strict;

# Setzt ein Array in ein Objekt um
sub new{
  my $class = shift;
  my $maps  = shift; # {3 => 'Day', 4 => 'Month', 5 => 'Year'}
  my $aref  = shift; # array als referenz von localtime, stat, etc.
  return if ref $maps ne 'HASH';
  return if ref $aref ne 'ARRAY';
  my $self  = {};
  for(my $i = 0; $i < scalar(@$aref); $i++){
    $self->{$maps->{$i}} = $aref->[$i] if exists $maps->{$i};
  }

  return bless $self, $class;
}

package main;

use strict;
use warnings;
use Data::Dump qw(dump);

# Erste Zeile sei
my $z1 = "Name,Vorname,Alter";
my @header = split ",", $z1;
my $helper = {};
foreach my $i(0..$#header){
        $helper->{$i} = $header[$i];
}

#print dump $helper; # { "0" => "Name", 1 => "Vorname", 2 => "Alter" }

my $result = {};
my $i = 1; # Zeilennummer
while(my $line = <DATA>){
        chomp $line;
        my $o = Names->new($helper, [split ",", $line]);
        $result->{$i} = $o;
        $i++;
}

print dump $result;
#{
#  1 => bless({ Alter => 45, Name => "Meier", Vorname => "Hans" }, "Names"),
#  2   => bless({ Alter => 54, Name => "Hansel", Vorname => "Horst" }, "Names"),
#  3   => bless({ Alter => 33, Name => "Horst", Vorname => "Anna" }, "Names"),
#}


# CSV
__END__
Meier,Hans,45
Hansel,Horst,54
Horst,Anna,33

########################################################################
Bitte ignorieren
########################################################################

Quote
wie kriege ich es hin, dass der Key "Name" die Values "Meyer" und "Schmidt" zugeweisen bekommt?

mein erster Vorschlag wäre ein Array als Value, bzw. eine Referenz auf das Array:

Code (perl): (dl )

  $hash{Name} = ['Vorname','Alter'];

Rosti

Edit: Mein zweiter Vorschlag hängt davon ab, wie Dir mein Erster gefällt ;)
Last edited: 2011-04-19 20:06:26 +0200 (CEST)

Linuxer

2011-04-19 17:23

User since
2006-01-27
3890 Artikel
HausmeisterIn

Ich würde die CSV-Daten mit Text::CSV einlesen; dazu dürfte es hier schon Diskussionen geben.

Dann würde ich die erste Zeile in einen separaten Array lesen; damit hast Du die Spaltennamen separat vorliegen und kannst darauf zurückgreifen.

Danach würde ich alle restlichen Datensätze/Zeilen einlesen und die Daten im Hash unter Verwendung des Arrays mit den Spaltennamen in den Hash packen.

meine Beiträge: I.d.R. alle Angaben ohne Gewähr und auf Linux abgestimmt!
Die Sprache heisst Perl, nicht PERL. - Bitte Crossposts als solche kenntlich machen!
+2 replies

topeg

2011-04-19 17:38

User since
2006-07-10
2611 Artikel
BenutzerIn

user image

2011-04-19T14:58:29 PETER_PAN2009
Code (perl): (dl )
my %hash = map { $inhalt[0] => 1 } @inhalt;

Der Code erzeugt in %hash nur Name => 1. Ich vermute mal das ist nicht das was du willst.

Hier ein Beispiel wie man es machen kann:

Code (perl): (dl )

#!/usr/bin/perl
use strict;
use warnings;
use Text::CSV;

my $file='namen.csv';

open(my $fh, '<', $file) or die("ERROR open $file ($!)\n");

my $csv = Text::CSV->new ();

# first line
my $key_names=$csv->getline( $fh );

# Array of hashes
my @data;

# read File
while( my $row = $csv->getline( $fh ) )
{
  my $value={};
  $value->{$key_names->[$_]}=$row->[$_] for(0..$#$key_names);
  push(@data,$value);
}

# Formated Output
use Data::Dumper;
print Dumper(\@data);

Die Ausgabe ist der Art:

Code: (dl )

$VAR1 = [
          {
            'Vorname' => 'Peter',
            'Alter' => '56',
            'Name' => 'Meyer'
          },
          {
            'Vorname' => 'Andre',
            'Alter' => '74',
            'Name' => 'Schmidt'
          }
        ];

Was, wie ich denke, deiner Vorstellung entspricht.

PETER_PAN2009

2011-04-20 20:57

User since
2009-08-24
111 Artikel
BenutzerIn

topeg das ist es...DANKE!

ps. an alle anderen natürlich ebenfalls ein DANKE für die Unterstützung :-)

Gruß
Peter

View all threads created 2011-04-19 16:58.