Wert aus Zeile auslesen in Abhängigkeit von einem Wert der Zeile darüber? (Allgemeines zu Perl)

[thread]16055[/thread]

Wert aus Zeile auslesen in Abhängigkeit von einem Wert der Zeile darüber?

Leser: 25

Articles: hide open all | hide show old branches

+7 replies

cybermaid

2011-03-10 23:08

User since
2011-03-10
2 Artikel
BenutzerIn
[default_avatar]

Hallo und schönen Abend zusammen,
ich habe jetzt einige Stunden lang gesucht, aber keine Lösung gefunden, die mich zum gewünschten Ergebnis gebracht hat.
Ich möchte im Grunde etwas ganz Einfaches (und ich bin mir sicher, dass der Weg dahin schon tausendmal erklärt wurde - habe es leider nicht gefunden).

Ich möchte aus einer Datei (VP2) einen Wert aus einer bestimmten Zelle der Zeile x auslesen, aber nur, wenn in der Zeile davor (also x-1) in einer bestimmten anderen Zelle ein bestimmter Eintrag (nämlich ein f) ist.
Also: nur wenn in Zelle $auslese1[$spalte7] der Zeile x-1 ein "j" ist, soll (nach Vorliegen anderer Voraussetzungen, die sich aber alle auf die Zeile x beziehen) aus der Zelle $auslese1[$spalt1] der Zeile x der Wert entnommen werden.

Das Ganze möchte ich in den folgenden Code einbauen (der - ich weiß - alles andere als elegant und schon gar nicht sparsam ist, aber der Rest des Scripts funktioniert und ich kann leider nicht alles umbauen):

Code: (dl )

while(<VP2>)						
{$zaehler++;						
	if ($zaehler < $anfang || $zaehler > $ende)
		{next;}
chomp;							
@auslese1 = split (/\t/, $_); 				

{

if ($auslese1[$spalt7] eq "j") 
	  {if ($auslese1[$spalt2] eq "Gewonnen")  
		{print RELRE "$auslese1[$spalt1]\t";}	
	   elsif($auslese1[$spalt2] eq "Verloren")

}
}
}

Versucht habe ich schon folgendes:

Code: (dl )

while(<VP2>)						
{$zaehler++;						
	if ($zaehler < $anfang || $zaehler > $ende)
		{next;}
chomp;							
@auslese1 = split (/\t/, $_); 				

if ($auslese1[$spalte7] eq "j")
	{next;}

{

if ($auslese1[$spalt7] eq "j") 
	  {if ($auslese1[$spalt2] eq "Gewonnen")  
		{print RELRE "$auslese1[$spalt1]\t";}	
	   elsif($auslese1[$spalt2] eq "Verloren")

}
}
}

und folgendes:

Code: (dl )

while(<VP2>)						
{$zaehler++;						
	if ($zaehler < $anfang || $zaehler > $ende)
		{next;}
chomp;							
@auslese1 = split (/\t/, $_); 				

if ($auslese1[$spalt7] eq "j")
{$zaehler = ($zaehler + 1);


{

if ($auslese1[$spalt7] eq "j") 
	  {if ($auslese1[$spalt2] eq "Gewonnen")  
			{print RELRE "$auslese1[$spalt1]\t";}

und folgendes (wobei: $anfangtv1 eine Zeile früher als $anfang bedeutet und $endetv1 eine Zeile früher als $ende ist):

Code: (dl )

while(<VP2>)						
{$zaehler++;						
	if ($zaehler < $anfang || $zaehler > $ende)
		{next;}
chomp;							
@auslese = split (/\t/, $_); 				

$zaehler10++;
	if ($zaehler10 < $anfangtv1 || $zaehler10 > $endetv1)
		{next;}

chomp;
@auslese10 = split (/\t/, $_);


if ($auslese10[$spalt7] eq "j")

{

if ($auslese1[$spalt7] eq "j") 

	  {if ($auslese1[$spalt2] eq "Gewonnen")  
			{print RELRE "$auslese1[$spalt1]\t";}	
	   elsif($auslese1[$spalt2] eq "Verloren")

Über Anregungen wäre ich Euch sehr dankbar!
Liebe Grüße
- C -

FIFO

2011-03-11 00:19

User since
2005-06-01
469 Artikel
BenutzerIn

user image

Hi,

Du könntest die Daten der vorangehenden Zeile in einem eigenen Array außerhalb der Schleife speichern:

Code (perl): (dl )

my @auslese_alt;
my @auslese_neu;

READ_LINE:
while (my $line = <VP2>) {
    
    @auslese_alt = @auslese_neu;  # Kopie der letzten Zeile bzw. Felder
    
    $zaehler++;                                         
    next READ_LINE if $zaehler < $anfang or $zaehler > $ende;
    
    chomp($line);
    
    @auslese_neu = split (/\t/, $line);                                 
    next READ_LINE unless @auslese_alt; # noch keine Vor-Daten eingelesen
    
    if ($auslese_alt[$spalt7] eq "j") {
        if ($auslese_neu[$spalt2] eq "Gewonnen"){
            print RELRE "$auslese_neu[$spalt1]\t";
        }       
        elsif ($auslese_neu[$spalt2] eq "Verloren") {
            # mach was anderes
        }
    }
}

Wenn Du in Perl weiterkommen willst, ist unbedingt empfehlenswert, sich mit use strict; und use warnings; abzusichern :)

Viel Erfolg noch, Gruß FIFO

Everyone knows that debugging is twice as hard as writing a program in the first place. So if you're as clever as you can be when you write it, how will you ever debug it? -- Brian Kernighan: "The Elements of Programming Style"

pktm

2011-03-11 00:22
User since
2003-08-07
2921 Artikel
BenutzerIn
Hallo cybermaid!

So für den Anfang würde ich Dir dringend anraten, deinen Code einfach einzurücken.
Immer, wenn du einen Code-Block auf machst ( öffnende geschweifte Klammer { ) rückst du alles nachfolgende um einen Tabulator ein. Immer wenn du eine geschweifte Klammer zu machst, machst du einen Tabulator weniger.

Dann siehst du auch die Fehler in deinem Code, z.B. dass deine Anweisungen außerhalb der Schleifen liegen und deine Abfragen deshalb nie so ausgeführt werden können, wie du Dir das vorstellst.

Und der nächste Schritt wäre dann, mit strict und warnings zu arbeiten.

Hier mal ein Beispielcode, der etwas ähnliches macht (ungetestet, aber um Welten lesbarer und verständlicher):
Code (perl): (dl )

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18

#!perl use strict; use warnings; my @zeilen = (qw/a c b f g rt d/); my $vorherige_zeile = ''; foreach my $aktuelle_zeile ( @zeilen ) { chomp($aktuelle_zeile); if( $aktuelle_zeile eq 'rt' and $vorherige_zeile eq 'g' ) { print "$vorherige_zeile stand vor $aktuelle_zeile\n"; last; } # -- letzte Zeile merken $vorherige_zeile = $aktuelle_zeile; }
Grüße, pktm
http://www.intergastro-service.de (mein erstes CMS :) )
+4 replies

FIFO

2011-03-11 08:20

User since
2005-06-01
469 Artikel
BenutzerIn

user image

Moin,

eine weitere Möglichkeit: Die ganze Datei in einem "Array of Arrays" ablegen und dann darauf zugreifen:

Code (perl): (dl )

my @auslese;

# Speichern
while (my $line = <VP2>) {
    chomp $line;
    push @auslese, [split("\t", $line)];
}

# Zugriff
for my $x (1 .. $#auslese) { # mit 2. Zeile anfangen
    next if $auslese[$x-1][$spalt7] ne "j";
    if ($auslese[$x][$spalt2] eq "Gewonnen") {
        print RELRE "$auslese1[$spalt1]\t";
    }
    elsif ($auslese[$x][$spalt2] eq "Verloren") {
        print RELRE "Du Versager!";
    }
}

Was für Dich passender ist hängt z.B. davon ab, wie oft du die Datei einlesen und verarbeiten musst (bei "1x einlesen, oft verarbeiten" ist die AoA-Variante besser), aber die Konzepte sollten verständlich sein.

Gruß FIFO

Editiert von FIFO: typo

Editiert von FIFO: noch nicht wach :)
Last edited: 2011-03-11 08:33:52 +0100 (CET)

+3 replies

FtR

2011-03-11 11:55

User since
2003-08-20
39 Artikel
BenutzerIn
[default_avatar]

Hi,
Das mit den AoA solltest du aber nur machen wenn deine Inputdatei klein ist.

Beispiel Input-Datei

Code: (dl )

nix nix nix nix nix nix nix
nix nix nix nix nix nix nix
nix nix nix nix nix nix nix
nix Peter nix Jo nix nix nix
nix Sieger1 nix nix nix nix nix
nix nix nix nix nix nix nix
nix nix nix nix nix nix nix
nix nix nix nix nix nix nix
nix FRED nix Jo nix nix nix
nix Sieger2 nix nix nix nix nix
nix nix nix nix nix nix nix
nix ROLF nix Jo nix nix nix
nix Sieger2 nix nix nix nix nix

Beispiel code

Code (perl): (dl )

#/usr/bin/perl -w 
use strict;
my $line;          # aktuelle Zeile      
my @linebuffer;    # Speicher für den Array der  zeile n-1 
my @workbuffer;    # Array der aktuelle Zeile 
open (IN,"_input_");

while ($line= <IN>)  # Zeilenweise lesen 
{
    @workbuffer = split (" ", $line);   # in array zerlegen 

    if (@linebuffer) {   # Test ob in der Zeile n-1 was erkannt wurde 
        if  ($workbuffer[1] eq "Sieger2"){
            print $linebuffer[1],"\t",$linebuffer[3],"\t",$workbuffer[1],"\n";
        }
        @linebuffer = undef;  # Zeile n-1 löschen  
    }

     if  ($workbuffer[3] eq "Jo"){
        @linebuffer = @workbuffer;
     }

}

Ausgabe

Code: (dl )

1
2

FRED	Jo	Sieger2
ROLF	Jo	Sieger2

Viel Spass
Last edited: 2011-03-11 13:16:54 +0100 (CET)

Code: ()

1
2

print&f(($_=(3x3)."3+33")=~s=3(?![^3]|$)=&f=eg);
sub f{eval(@_?$_:"'$&+'x3");}

+2 replies

cybermaid

2011-03-11 12:52

User since
2011-03-10
2 Artikel
BenutzerIn
[default_avatar]

Zunächst einmal vielen lieben Dank für die schnellen und zahlreichen Tipps. Mit der ersten Variante habe ich leider noch keinen Erfolg gehabt und die anderen werde ich dann wohl leider erst heute Abend ausprobieren können. Ich melde mich wieder, sobald ich Erfolge verzeichnen kann!

Dank an Euch und gute Grüße
- C -

FIFO

2011-03-11 13:39

User since
2005-06-01
469 Artikel
BenutzerIn

user image

Was funktioniert denn nicht? Welche Fehlermeldungen erhältst Du?
Es ist immer schwierig, die Gedanken hinter einem Codebruchstück zu erraten.

Also bau am besten eine lauffähige Miniversion und poste die hier.
Tip: statt einer Datei kannst Du dabei das DATA-Segment verwenden. Als Beispiel:

Code (perl): (dl )

#!/usr/bin/perl

use warnings;
use strict;

my @alte_zeile;
my @neue_zeile;
my $spalte_i = 2;  # 3. Feld in der Zeile
my $spalte_k = 4;  # 5. Feld in der Zeile
my $zaehler;

while (my $line = <DATA>) {  # statt Datei
    chomp $line;
    $zaehler++;
    @alte_zeile = @neue_zeile;
    @neue_zeile = split(":", $line);
    next unless @alte_zeile;
    if ($alte_zeile[$spalte_i] eq "12") {
        print "Treffer '12' in Spalte $spalte_i\n";
        my $feld_k_neu = $neue_zeile[$spalte_k];
        if ($feld_k_neu eq "x") {
            print "\tTreffer 'x' in in Zeile $zaehler, Spalte $spalte_k\n";
        }
        elsif ($feld_k_neu eq "w") {
            print "\tTreffer 'w' in in Zeile $zaehler, Spalte $spalte_k\n";
        }
        else {
            print "\tKein Treffer in Zeile $zaehler.\n";
        }
    }
}
__DATA__
zeile1:foo:2:bar:x:test
Zeile2:baz:12:bla:d:blub
zeile3:urbi:7:orbi:w:maus
zeile4:lolek:1:bolek:y:elefant
zeile5:foo:2:bar:x:test
Zeile6:baz:12:bla:d:blub
zeile7:urbi:7:orbi:x:maus
zeile8:lolek:1:bolek:y:elefant

Ausgabe:

Code: (dl )

Treffer '12' in Spalte 2
	Treffer 'w' in in Zeile 3, Spalte 4
Treffer '12' in Spalte 2
	Treffer 'x' in in Zeile 7, Spalte 4

Editiert von FIFO: output ergänzt
Last edited: 2011-03-11 13:42:01 +0100 (CET)

View all threads created 2011-03-10 23:08.