#!/usr/bin/perl

use strict;
use warnings;

my $dir = '/home/jars/community_test/';

my %files;
my @keep;
my @to_delete;

opendir my $dir_h, $dir or die "Can't open directory $dir: $!";
while ( my $entry = readdir $dir_h ) {

    # hole den namen und den "counter"
    my ($name,$counter) = $entry =~ m{ (.*?) (\d+) [a-z] \.txt }x;

    # wenn es keine Datei mit dem Muster ist, mache einfach mit
    # der nächsten Datei weiter
    next if !($name and $counter);

    # speichere den namen und das "zählkürzel"
    # $files->{TestA_}->{001} = 1
    push @{ $files{$name}->{$counter} }, $entry;
}
closedir $dir_h;

# laufe über die Namen (z.B. TestA001, TestA002, ...)
for my $name ( keys %files ) {

    # sortiere die "zählkürzel" absteigend. Das "höchste" wird in
    # $keep gespeichert, der Rest in @delete
    my ($keep,@delete) = sort{ $b cmp $a }keys %{ $files{$name} };

    # setze den Dateinamen wieder zusammen und speichere es in @keep
    push @keep, map{ $dir . $_ }@{ $files{$name}->{$keep} };

    # für jedes andere Zählkürzel wird der Dateiname zusammengesetzt und
    # in @to_delete gespeichert.
    push @to_delete, map{ $dir . $_ }map{ @{ $files{$name}->{$_} } }@delete;
}

print "Keep: @keep\nDelete: @to_delete\n";