Datenstruktur mit SOAP::Data (Fragen zu Perl-Modulen)

[thread]15136[/thread]

Datenstruktur mit SOAP::Data

Leser: 14

Articles: hide open all | hide show old branches

+5 replies

Gast bianca

2010-06-13 17:32

Guten Tag!
Es muss eine SOAP Datenstruktur in der Art wie diese für einen Request "gebaut" werden:

Code: (dl )

[item] => Array 
( 
["country"] => NL 
) 
[item] => Array 
( 
["step"] => 1 
)

Dafür habe ich folgendes versucht:

Code (perl): (dl )

#!/usr/bin/perl -w 
use strict; 
use warnings; 
use diagnostics; 
use Data::Dumper; 
use SOAP::Lite; 
my %data_to_send_in_soap_map = ( 
  'country' => 'NL', 
  'step' => '1', 
); 
my (@soap_map,@params); 
foreach my $key (keys %data_to_send_in_soap_map) { 
  push @soap_map, 
    \SOAP::Data -> name ('item') -> value ( 
      SOAP::Data -> name ($key) -> value ($data_to_send_in_soap_map{$key}), 
    ) 
  ; 
} 
@params = ( 
  SOAP::Data -> name ('params') -> value (@soap_map) 
); 
print Dumper (\@params);

Damit fehlt mir allerdings das 'item' in der Struktur, es kommt so beim Server an:

Code: (dl )

Array (
  [country] => NL
)
Array (
  [step] => 1
)

Wenn ich nun dies hier mit eckigen Klammern versuche:

Code (perl): (dl )

#!/usr/bin/perl -w 
use strict; 
use warnings; 
use diagnostics; 
use Data::Dumper; 
use SOAP::Lite; 
my %data_to_send_in_soap_map = ( 
 'country' => 'NL', 
 'step' => '1', 
); 
my (@soap_map,@params); 
foreach my $key (keys %data_to_send_in_soap_map) { 
 push @soap_map, 
  \SOAP::Data -> name ('item') -> value ([ 
    SOAP::Data -> name ($key) -> value ($data_to_send_in_soap_map{$key}), 
  ]) 
 ; 
} 
@params = ( 
 SOAP::Data -> name ('params') -> value (@soap_map) 
); 
print Dumper (\@params);

dann ist 'item' zwar vorhanden aber alle keys haben den Inhalt '0':

Code: (dl )

Array (
  [item] => Array(
    [0] => NL
  )
)
Array (
  [item] => Array(
    [0] => 1
  )
)

Der ganze Request als XML soll so aussehen:

Code: (dl )

<params xsi:type="ns2:Map">
<item>
<key xsi:type="xsd:string">country</key>
<value xsi:type="xsd:string">NL</value>
</item>
<item>
<key xsi:type="xsd:string">step</key>
<value xsi:type="xsd:string">1</value>
</item>
</params>

Wie muss ich das für SOAP::Data richtig formulieren?

Vielen Dank

Crosspost: http://perlguru.com/gforum.cgi?post=46909

+4 replies

topeg

2010-06-14 02:50

User since
2006-07-10
2611 Artikel
BenutzerIn

user image

Schau mal hier: msg #137607 Speziell:

Quote
- Der Parameter für SOAP::Data->value($param) muss immer eine
Referenz sein - entweder eine Array-Referenz [] oder eine Referenz auf
ein Objekt ...

Und vergleiche das mit:

Guest bianca

Code (perl): (dl )

      SOAP::Data -> name ($key) -> value ($data_to_send_in_soap_map{$key}),

Code (perl): (dl )

SOAP::Data -> name ('params') -> value (@soap_map)

Ich würde vermuten, dass es so richtig ist:

Code (perl): (dl )

      \SOAP::Data -> name ($key) -> value ($data_to_send_in_soap_map{$key}),

Code (perl): (dl )

SOAP::Data -> name ('params') -> value(\@soap_map);

vollständiger Code:

Code (perl): (dl )

#!/usr/bin/perl -w
use strict;
use warnings;
use Data::Dumper;
use SOAP::Lite;
my %data_to_send_in_soap_map = (
  'country' => 'NL',
  'step' => '1',
);

my (@soap_map,@params);
foreach my $key (keys %data_to_send_in_soap_map) {
  push @soap_map,
    \SOAP::Data->name('item')->value([
      SOAP::Data->name('key')->value($key),
      SOAP::Data->name('value')->value($data_to_send_in_soap_map{$key})
    ]);
}

@params = (
  SOAP::Data->name('params')->type('ns2:Map')->value(\@soap_map)
);

print Dumper (\@params);

EDIT:
Code korrigiert
Last edited: 2010-06-14 04:02:47 +0200 (CEST)

+3 replies

Gast bianca

2010-06-14 08:36

Danke topeg!
Allerdings wird diese Variante vom Server so empfangen:

Code: (dl )

Array
(
    [item] => Array
        (
            [0] => country
            [1] => NL
        )

)

Der Server scheint es nicht als key-value Paare sondern andres zu erkennen.

Als XML sieht diese Variante so aus:

Code: (dl )

<?xml version="1.0" encoding="UTF-8"?>
<soap:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:soapenc="ht
tp://schemas.xmlsoap.org/soap/encoding/" xmlns:xsd="http://www.w3.org/2001/XMLSchema" soap:encodingStyle="http://schemas.xml
soap.org/soap/encoding/" xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
<soap:Body>
<foo>
<params><c-gensym3>
<item>
<key>country</key>
<value>NL</value>
</item>
</c-gensym3>
<c-gensym4>
<item>
<key>step</key>
<value>1</value>
</item>
</c-gensym4>
</params>
</foo>
</soap:Body>
</soap:Envelope>

Vielleicht erkennt der Server das jetzt anders wegen dieser c-gensym Tags oder der fehlenden xsd Bezeichnungen?

Den Request als XML kann man übrigens so provozieren:
use SOAP::Lite +trace => 'all'; als Aufruf
dann ein Objekt generieren mit einer bewusst falschen URL: my $soap = SOAP::Lite->proxy('binnichtda')->autotype(0);
und am Ende eine nicht existente Funktion aufrufen: $soap->call('foo',@params);

Komplett inkl. topeg's Vorschlag:

Code (perl): (dl )

#!/usr/bin/perl -w
use strict;
use warnings;
use Data::Dumper;
use SOAP::Lite +trace => 'all';
my $soap = SOAP::Lite->proxy('http://binnicihtda:8080')->autotype(0);
my %data_to_send_in_soap_map = (
  'country' => 'NL',
  'step' => '1',
);

my (@soap_map,@params);
foreach my $key (keys %data_to_send_in_soap_map) {
  push @soap_map,
    \SOAP::Data->name('item')->value([
      SOAP::Data->name('key')->value($key),
      SOAP::Data->name('value')->value($data_to_send_in_soap_map{$key})
    ]);
}

@params = (
  SOAP::Data->name('params')->type('ns2:Map')->value(\@soap_map)
);

print Dumper (\@params);
$soap->call('foo',@params);

Ausgabe gekürzt:

Code: (dl )

SOAPAction: "#foo"

<?xml version="1.0" encoding="UTF-8"?><soap:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:soapenc="ht
tp://schemas.xmlsoap.org/soap/encoding/" xmlns:xsd="http://www.w3.org/2001/XMLSchema" soap:encodingStyle="http://schemas.xml
soap.org/soap/encoding/" xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/"><soap:Body><foo><params><c-gensym3><item><ke
y>country</key><value>NL</value></item></c-gensym3><c-gensym4><item><key>step</key><value>1</value></item></c-gensym4></para
ms></foo></soap:Body></soap:Envelope>

Last edited: 2010-06-14 08:51:09 +0200 (CEST)

+2 replies

topeg

2010-06-14 13:34

User since
2006-07-10
2611 Artikel
BenutzerIn

user image

Sei froh das ich etwas Zeit hatte... :-)

Das sieht doch nicht schlecht aus:

Code: (dl )

<?xml version="1.0" encoding="UTF-8"?>
<soap:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
               xmlns:soapenc="http://schemas.xmlsoap.org/soap/encoding/"
               xmlns:xsd="http://www.w3.org/2001/XMLSchema"
               soap:encodingStyle="http://schemas.xmlsoap.org/soap/encoding/"
               xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">

  <soap:Body>
    <get_form xmlns="http://dev.iban-bic.com/Riban/soap2/?wsdl">
      <params soapenc:arrayType="xsd:anyType[2]" xsi:type="tns:Map">
        <item>
          <key xsi:type="xsd:string">country</key>
          <value xsi:type="xsd:string">NL</value>
        </item>
        <item>
          <key xsi:type="xsd:string">step</key>
          <value xsi:type="xsd:string">1</value>
        </item>
      </params>
      <user xsi:type="xsd:string">name</user>
      <password xsi:type="xsd:string">pass</password>
    </get_form>
  </soap:Body>
</soap:Envelope>

Code:

Code (perl): (dl )

#!/usr/bin/perl
use strict;
use warnings;

sub BEGIN
{ unshift(@INC,'.'); }

use Data::Dumper;
use SOAP::Lite +trace => 'all';


my $soap = SOAP::Lite ->uri( 'http://dev.iban-bic.com/Riban/soap2/?wsdl' );
$soap->proxy( 'http://bla.home:8888' );
#$soap->proxy('http://dev.iban-bic.com/Riban/soap2/');

my %data_to_send_in_soap_map = (
  'country' => 'NL',
  'step' => '1',
);

my $user='name';
my $pass='pass';

my (@soap_map,@params);
foreach my $key (keys %data_to_send_in_soap_map) {
  push @soap_map,
    \SOAP::Data->value(
      SOAP::Data->name('key'   => $key                           )->type('xsd:string'),
      SOAP::Data->name('value' => $data_to_send_in_soap_map{$key})->type('xsd:string'),
    );
}

$soap->get_form(
  SOAP::Data->name('params'   => \@soap_map)->type('tns:Map'),
  SOAP::Data->name('user'     => $user     )->type('xsd:string'),
  SOAP::Data->name('password' => $pass     )->type('xsd:string'),
);

Das setzen der Typen ist nicht zwingend aber ich weiß nicht wie genau es der Server nimmt.

Gast bianca

2010-06-14 13:54
Das ist in der Tag perfekt!
DANKE DIR!!!

Hatte auch die ganze Zeit rumgetüftelt aber immer wenn ich dachte kurz davor gewesen zu sein, wurde es abgeschmettert :(

Meine letzte war diese hier bis gerade eben:
Code (perl): (dl )

1 2 3 4 5 6 7 8 9

foreach my $key (keys %data_to_send_in_soap_map) { push @soap_map,[ SOAP::Data->name('key')->value($key), SOAP::Data->name('value')->value($data_to_send_in_soap_map{$key}) ]; } @params = ( SOAP::Data->name('params')->type('ns2:Map')->value(\@soap_map) );
Die sah auch ganz gut aus, hatte nur noch ein paar viele Beschreibungen in den Tags und mir fehlten noch User und Passwort.
Last edited: 2010-06-14 13:55:29 +0200 (CEST)

View all threads created 2010-06-13 17:32.