In anonymes Hash umwandeln - #60193 (Allgemeines zu Perl)

pKai

2005-11-16 12:46

User since
2005-02-18
357 Artikel
BenutzerIn
[default_avatar]

Code: (dl )

use strict;
use warnings;
use Data::Dumper ();

my $S = {};

sub splitTo {
    my ($pH, $pA, $leaf) = @_;
    $pA = [ grep $_, split /\//, $pA ] unless ref $pA;
    return $leaf unless @$pA;
    my $nxt = shift @$pA;
    my $pHN = ref $pH->{$nxt} ? $pH->{$nxt} : {};
    $pH->{$nxt} = splitTo($pHN, $pA, $leaf);
    $pH;
}

splitTo($S, 'foo/bar', 'oops');
splitTo($S, 'foo/bar/baz', '\\o/');
splitTo($S, 'foo/gnu', 'gnat');

print Data::Dumper->Dump([$S], ['S']);

Code: (dl )

$S = {
       'foo' => {
                  'bar' => {
                             'baz' => '\\o/'
                           },
                  'gnu' => 'gnat'
                }
     };

Hier wird allerdings gnadenlos überschrieben:

Code: (dl )

1
2
3

splitTo($S, 'foo/gnu', 'gnat');
splitTo($S, 'foo/bar/baz', '\\o/');
splitTo($S, 'foo/bar', 'oops');

Code: (dl )

$S = {
       'foo' => {
                  'bar' => 'oops',
                  'gnu' => 'gnat'
                }
     };

Edit: Wenn überschreiben von Hashrefs durch Skalare nicht gewünscht ist, muss es in der sub

Code: (dl )

    return(keys %$pH ? $pH : $leaf) unless @$pA;

in der return-Zeile heißen.

Edit2: Und noch der Vollständigkeit halber: Wenn im Eingabepfad "0" als Teil auftreten kann, die Prüfung im grep von $_ auf length $_ umstellen\n\n

I sense a soul in search of answers.