#!/usr/bin/perl
use strict;
use warnings;

# Das ist die Datei, die ich Textdokument als Hex schreibe
my $file = 'C:\Games\kl.txt';
# temporäre Datei
my $tempfile = 'C:\Users\Shiu\hex.txt';

#-----------------------------------------------------------------------
# Kodier- und Dekodierfunktionen

# Funktion zum kodieren eines binären Strings
# bin -> hex
sub verpacken
{ return join( ' ', map { unpack 'h*', $_ } split( //, $_[0] ) ); }


# Funktion zum dekodieren eines binären Strings
# hex -> bin
sub entpacken
{
  my $data = shift;

  # alles löschen was nicht Hexcode ist
  $data=~tr/0-9a-fA-F//dc;

  # das ganze als Hexstring packen
  return pack( 'h*' ,$data );
}

#-----------------------------------------------------------------------
# Dateioperationen

# datei schreiben
sub writeFile
{
  my $file = shift;
  my $data = shift;
  open(my $fh, '>', $file) or return 0; # 0 zurück wenn Fehler
  print $fh $data;
  close($fh);
  return 1; # 1 zurück wenn alles OK
}

# Datei ohne Konvertierung durch Perl schreiben
sub writeRawFile
{
  my $file=shift;
  my $data=shift;
  open(my $fh, '>', $file) or return 0; # 0 zurück wenn Fehler
  binmode($fh);
  print $fh $data;
  close($fh);
  return 1; # 1 zurück wenn alles OK
}

# Datei als ganzes Lesen
sub readFile
{
  my $file=shift;

  local $/=undef;
  open(my $fh, '<', $file) or return undef; # undef zurück wenn Fehler
  my $data=<$fh>;
  close($fh);

  return $data; # Daten zurück wenn alles OK
}

# Datei als ganzes lesen ohne konvertierung durch Perl
sub readRawFile
{
  my $file=shift;

  local $/=undef;
  open(my $fh, '<', $file) or return undef; # undef zurück wenn Fehler
  binmode($fh);
  my $data=<$fh>;
  close($fh);

  return $data; # Daten zurück wenn alles OK
}


########################################################################
# Das Hauptprogramm
########################################################################

# lesen und Kodieren
# am Ende des blocks werden die Variablen von perl gelöscht
# Damit verhindert man unnötigen "Datenleichen" im Speicher
{
  my $raw_data=readRawFile($file);
  die("Can't read $file ($!)\n") unless(defined $raw_data);

  my $hex_data=verpacken($raw_data);

  writeFile($tempfile,$hex_data) or die("Can't write $tempfile ($!)\n");
}

# lesen und dekodieren
{
  my $hex_data=readFile($tempfile);
  die("Can't read $tempfile ($!)\n") unless(defined $hex_data);

  my $raw_data=entpacken($hex_data);

  print $raw_data;
}