package PersonenDB;
use strict;
use warnings;
use IO::File;
use Fcntl qw(:flock :seek);
use utf8;

# Trenner
my $separator=";";
# Zeilenende
my $lineend="\x0A";

my @force_names=qw(vorname nachname address);
my @optional_names=qw(person website email dienstzeit dienstgrad dienststellung einheit nummer typ);
my @all_names=(@force_names,@optional_names);

my @typen=(
 ['Minenleger',     'KSS Projekt 1159 (Koni-class)'     ],
 ['Minenleger',     'MSR Projekt 89.2 (Kondor-class)'   ],
 ['U-Jagd',         'U-Jagd Projekt 133 (Parchim-class)'],
 ['Landungsschiff', 'LSM Projekt 108 (Frosch-class)'    ],
);

sub typen{ return @typen; }
sub key_names{ return @all_names; }

# PersonenDB->new($filename);
sub new
{
  my $class=shift;
  my $filename=shift;

  my $self={};
  $self->{filename}=$filename;
  $self->{data}    =undef;
  $self->{fh}      =undef;
  $self->{error}   ='';

  bless($self,$class);

  $self->read();

  return $self;
}

sub error
{
  my $self=shift;
  my $err=$self->{error};
  $self->{error}='';
  return $err;
}

# Benutzer Sortieren
sub sort
{
  my $self=shift;

  @{$self->{data}}=sort __sort @{$self->{data}};

  return 1;
}

# generisches Golen von Nutzern
sub get_by
{
  my $self=shift;
  my $key=shift;
  my $val=shift;

  return __filter($self->{data},$key,$val);
}

# alle benutzer mit dem Vornamen
sub get_by_vorname
{
  my $self=shift;
  my $name=shift;

  return __filter($self->{data},'vorname',$name);
}

# alle Benutzer mit dem Nachnamen
sub get_by_nachname
{
  my $self=shift;
  my $name=shift;

  return __filter($self->{data},'nachname',$name);
}

# alle nutzer mit dem Vormanem und namen
sub get_by_name
{
  my $self=shift;
  my $vorname=shift;
  my $nachname=shift;

  my @l=__filter($self->{data},'nachname',$vorname);
  @l=__filter(\@l,'vorname',$nachname);
  return @l;
}

# allen Nutzter mit der Email
sub get_by_email
{
  my $self=shift;
  my $email=shift;
  return __filter($self->{data},'email',$email);
}

# Existiert person?
sub exists
{
  my $self=shift;
  my $user=shift;
  my @l=$self->get_by_name($user->{vorname},$user->{nachname});
  unless(@l)
  {
    @l=$self->get_by_email($user->{email});
    return 0 unless(@l);
  }
  return 1;
}

# daten lesen
sub read
{
  my $self=shift;

  # Datei öffnen:
  return 0 unless($self->_open());

  my $fh=$self->{fh};

  # Datei sperren
  flock($fh,LOCK_EX);

  # zum Anfang der Datei
  $fh->seek(0,SEEK_SET);

  # Liste leeren
  $self->{data}=[];

  # format:
  #   Vorname\0Name\0Wohnort\0Webseite\0Mailadresse\0Dienstzeit\0Dienstgrad\0Dienststellung\x0A
  # zeilen die mir '\s*#' starten werden ignoriert!
  local $/=$lineend;
  while(my $line=<$fh>)
  {
    chomp($line);
    next if($line=~/^\s*#/);
    $line=~s/^\s*//;
    next unless($line);

    my @data=map{__unquote($_)}split($separator,$line);
    push(@{$self->{data}},{map{$all_names[$_] => $data[$_]}(0..$#all_names)});
  }

  # Datei entsperren
  flock($fh,LOCK_UN);

  # Liste sortieren:
  $self->sort();


  return 1;
}

# Person hinzufügen
sub add
{
  my $self=shift;
  my $data=shift;

  # nicht hinzufügen wenn nicht alle wichtigen daten vorhanden
  for(@force_names)
  {
    unless($data->{$_})
    {
      $self->{error}.= sprintf("%s ist Leer!\n",$_);
      return 0;
    }
  }

  # unnötige werde auf '' setzen.
  for(@optional_names)
  { $data->{$_}='' unless($data->{$_}); }

  # testen ob die Emailadersse korrekt ist
  if($data->{'email'})
  {
    unless($data->{'email'}=~/^[\w._%+-]+@[\w.-]+\.\w{2,4}$/)
    {
      $self->{error}.= sprintf("%s ist keine korrekte Emailadresse!\n",$data->{'email'});
      return 0;
    }
  }

  # nicht hinzufügen wenn schon vorhanen
  if($self->exists($data))
  {
    $self->{error}.= "Der Name ist schon Eingetragen!\n";
    return 0;
  }

  # Datei öffnen wenn nicht schon offen:
  return 0 unless($self->_open());

  # Daten serialisieren
  my $string="  ".join($separator,map{__quote($data->{$_})}@all_names).$lineend;

  my $fh=$self->{fh};

  # Datei sperren
  flock($fh,LOCK_EX);

  # zum Ende der Datei:
  $fh->seek(0,SEEK_END);

  # schreiben
  $fh->print($string);

  #das schreiben der Daten erzwingen
  $fh->flush();
  $fh->sync();

  # Datei Entsperren
  flock($fh,LOCK_UN);

  # zur Liste hinzufügen
  push(@{$self->{data}},$data);

  # sortieren
  $self->sort();

  return 1;
}

# alle Daten
sub all
{
  my $self=shift;
  return @{$self->{data}};
}

########################################################################
# privat

sub _open
{
  my $self=shift;
  # Datei öffnen wenn nicht offen
  $self->{fh}=IO::File->new() unless($self->{fh});
  if(!$self->{fh}->opened())
  {
    unless($self->{fh}->open($self->{filename},"+>>"))
    {
      $self->{error}.= "Die Datenbank lässt sich nicht öffnen!\n";
      return 0;
    }
  }
  return 1;
}

# sortierung
sub __sort
{
  for (qw(nachname address vorname))
  {
    my $x=lc($a->{$_}) cmp lc($b->{$_});
    return $x if($x != 0);
  }
  return 0;
}

# Geschützte Zeichen Entwerten
sub __quote
{
  my $val=shift;
  $val=~s/(%|\Q$separator\E|\Q$lineend\E)/'%'.join('%',map{sprintf('%03u',ord($_))}split('',$1))/egs;
  return $val;
}

# Entwertung rückgängig machen
sub __unquote
{
  my $val=shift;
  $val=~s/%(\d\d\d)/chr($1)/egs;
  return $val;
}

sub __filter
{
  my @liste=@{shift()};
  my $key=shift;
  my $value=shift;

  for my $pos (reverse(0..$#liste))
  {
    my $v=$liste[$pos];
    splice(@liste,$pos,1) if(!exists($v->{$key}) || $v->{$key} ne $value);
  }

  return @liste;
}

1;

<?xml version="1.0" ?>
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
    "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
  <head>
    <title>Kameradenfinder/Meldeliste für Besatzungsmitglieder</title>
    <meta http-equiv="Content-Type" content="text/html; charset=UTF-8" />
    <meta name="description" content="Kameradenfinder/Meldeliste für Besatzungsmitglieder" />
    <style type="text/css">
      body {
        background-color:#ffffea;
        color:#ffff91;
        font-family:verdana;
        text-align:left;
      }
      #all {
        position:absolute;
        top:0px;
        left:50%;
        width:0px;
      }
      #document {
        position:relative;
        left:-350px;
        padding:0em;
        margin-top:3em;
        background-color:#000000;
        border-width:9px;
        border-style:outset;
        border-color:gray;
        width:700px;
      }
      #document_top {
        padding-top:2em;
        margin-bottom:2em;
        text-align:center;
      }
      #document_form {
        margin-top: 3em;
        padding:0em;
      }
      #document_send {
        margin-bottom:2em;
        margin-left:1em;
        margin-right:1em;

        padding-left:0em;
        padding-right:0em;
        padding-top:2em;
        padding-bottom:2em;

        border-left-width:0em;
        border-right-width:0em;
        border-top-width:0.2em;
        border-bottom-width:0.2em;
        border-color:#ffff91;
        border-style:solid;

        text-align:center;
      }
      #title {
        font-family:verdana,tahoma,arial;
        font-size:2em;
        margin-right:2em;
        font-weight:bold;
      }
      .link {
        font-family:verdana;
        color:#ffff91;
        font-size:1.2em;
      }
      #form_list {
        list-style-type:none;
        list-style-position:outside;
      }
      #form_list > li {
        padding: 0.2em;
      }
      .form_text {
        font-size:0.9em;
        text-align:left;
        width:13em;
        float:left;
        white-space:nowrap;
        font-weight:bold;
      }
      .form_input {
        float:none;
      }
      .form_input > input {
        font-size:0.5em;
        background-color: #ffffe1;
        font-weight: bold;
        width:40em;
      }
      .form_input > textarea {
        font-size:0.5em;
        background-color: #ffffe1;
        font-weight: bold;
        width:40em;
        height:10em;
      }
      .form_input > select {
        font-size:0.5em;
        background-color: #ffffe1;
        font-weight: bold;
        width:40em;
      }
      #form_send {
        cursor: pointer;
        background-color: #00ff00;
        color: #00004a;
        font-family: verdana;
        font-weight: bold;
        padding:0.3em;
        margin-right:2em;
      }
      #form_reset {
        cursor: pointer;
        background-color: #ff0000;
        color: #00004a;
        font-family: verdana;
        font-weight: bold;
        padding:0.3em;
        margin-right:4em;
      }
    </style>
  </head>
  <body><div id="all">
    <div id="document">
      <div id="document_top">
        <span id="title">Meldeformular</span>
        <a class="link" href="<TMPL_VAR ACTION_SHOW>" title="Meldeliste lesen...">Meldeliste lesen...</a>
      </div>
      <form action="<TMPL_VAR ACTION_SEND>" method="post">
      <input type="hidden" name="action" value="send" />
        <div id="document_form">
          <ul id="form_list">
            <li>
              <div class="form_text" >Name:</div>
              <div class="form_input"><input    name="nachname"       maxlength="30" size="50" value="<TMPL_VAR nachname>" /></div>
            </li>
            <li>
              <div class="form_text" >Vorname:</div>
              <div class="form_input"><input    name="vorname"        maxlength="30" size="50" value="<TMPL_VAR vorname>" /></div>
            </li>
            <li>
              <div class="form_text" >Wohnort:</div>
              <div class="form_input"><input    name="address"        maxlength="30" size="50" value="<TMPL_VAR address>" /></div>
            </li>
            <li>
              <div class="form_text">E-Mail:</div>
              <div class="form_input"><input    name="email"          maxlength="30" size="50" value="<TMPL_VAR email>" /></div>
            </li>
            <li>
              <div class="form_text" >Homepage:</div>
              <div class="form_input"><input    name="website"       maxlength="30" size="50" value="<TMPL_VAR website>" /></div>
            </li>
            <li>
              <div class="form_text" >Zur Person:</div>
              <div class="form_input"><textarea name="person"         rows="4" cols="50" ><TMPL_VAR person></textarea></div>
            </li>
            <li>
              <div class="form_text" >Dienstzeit:</div>
              <div class="form_input"><input    name="dienstzeit"     maxlength="30" size="50" value="<TMPL_VAR dienstzeit>" /></div>
            </li>
            <li>
              <div class="form_text" >Dienstgrad:</div>
              <div class="form_input"><input    name="dienstgrad"     maxlength="30" size="50" value="<TMPL_VAR dienstgrad>" /></div>
            </li>
            <li>
              <div class="form_text" >Dienststellung:</div>
              <div class="form_input"><input    name="dienststellung" maxlength="30" size="50" value="<TMPL_VAR dienststellung>" /></div>
            </li>
            <li>
              <div class="form_text" >Einheit/Schiff:</div>
              <div class="form_input"><input    name="einheit"        maxlength="30" size="50" value="<TMPL_VAR einheit>" /></div>
            </li>
            <li>
              <div class="form_text" >Schiff - Bordnummer:</div>
              <div class="form_input"><input    name="nummer"         maxlength="30" size="50" value="<TMPL_VAR nummer>" /></div>
            </li>
            <li>
              <div class="form_text" >Schiff - Projekt:</div>
              <div class="form_input"><select   name="typ"            size="1" title="Typ auswählen">
                <option value="0" selected title="Schiffstyp auswählen">------------ Schiffstyp auswählen --------->>></option><TMPL_LOOP SELECT>
                <option value="<TMPL_VAR VALUE>" title="<TMPL_VAR TITLE>">&nbsp; <TMPL_VAR TEXT></option></TMPL_LOOP>
              </select></div>
            </li>
          </ul>
        </div>
        <div id="document_send">
          <input id="form_send"  title="Ich möchte mich in die Meldeliste eintragen." type="submit" value="EINTRAGEN">
          <input id="form_reset" title="Alles Mist noch mal neu."                     type="reset"  value="LÖSCHEN">
          <a class="link" href="<TMPL_VAR ACTION_SHOW>" title="Meldeliste lesen...">Meldeliste lesen...</a><br />
          <p><TMPL_VAR MESSAGE></p>
        </div>
      </form>
        &nbsp;
    </div></div>
  </body>
</html>

<?xml version="1.0" ?>
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
    "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
  <head>
    <title>Kameradenfinder/Meldeliste für Besatzungsmitglieder</title>
    <meta http-equiv="Content-Type" content="text/html; charset=UTF-8" />
    <meta name="description" content="Kameradenfinder/Meldeliste für Besatzungsmitglieder" />
    <style type="text/css">
      a {
        font-family:verdana;
        color:#ffff91;
        font-size:1em;
      }

      body {
        background-color:#ffffea;
        color:#ffff91;
        font-family:verdana;
        text-align:left;
      }

      #all {
        position:absolute;
        top:0px;
        left:50%;
        width:0px;
      }
      #document {
        position:relative;
        left:-350px;
        padding:0em;
        margin-top:3em;
        background-color:#000000;
        border-width:9px;
        border-style:outset;
        border-color:gray;
        width:700px;
      }
      #document_top {
        padding-top:2em;
        margin-bottom:2em;
        text-align:center;
      }
      #document_form {
        margin-top: 3em;
        padding:0em;
      }
      #personen_short {
        margin-bottom:2em;
        margin-left:1em;
        margin-right:1em;

        padding-left:0em;
        padding-right:0em;
        padding-top:2em;
        padding-bottom:2em;

        border-left-width:0em;
        border-right-width:0em;
        border-top-width:0.2em;
        border-bottom-width:0.2em;
        border-color:#ffff91;
        border-style:solid;

        text-align:left;
      }
      #personen_short ul {
        list-style-type: none;
      }
      #personen_short li {
        display: inline;
      }
      #personen_short li > a {
        min-width: 9em;
        display: -moz-inline-box;
        display: inline-block;
      }

      #personen_long {
        list-style-type: none;
        margin: 0em;
        padding: 0em;
      }

      #personen_long > li {
        padding-bottom:1em;
        margin: 1em;
        border-left-width:0em;
        border-right-width:0em;
        border-top-width:0em;
        border-bottom-width:0.2em;
        border-color:#ffff91;
        border-style:solid;
      }

      #personen_long > li > ul {
        margin: 0em;
        padding: 0em;
        list-style-type: none;
      }

      #document_bottom {
        margin-top:2em;
        margin-left:1em;
        margin-right:1em;

        padding-bottom:2em;
        padding-top:2em;

        border-left-width:0em;
        border-right-width:0em;
        border-top-width:0em;
        border-bottom-width:0.2em;
        border-color:#ffff91;
        border-style:solid;
        text-align:center;
      }

      #title {
        font-family:verdana,tahoma,arial;
        font-size:2em;
        margin-right:2em;
        font-weight:bold;
      }
      .link {
        font-size:1.2em;
      }

      .p_typ {
        font-size:0.8em;
        text-align:left;
        width:13em;
        float:left;
        white-space:nowrap;
      }

      .p_txt {
        float:none;
        font-size:0.8em;
        width:40em;
      }
    </style>
  </head>
  <body><div id="all">
    <div id="document">
      <div id="document_top">
        <span id="title">MeldeListe</span>
        <a class="link" href="<TMPL_VAR ACTION_INPUT>" title="Person Eingeben...">Person Eingeben...</a>
      </div>
      <div id="personen_short">
        <a name="TOP">NAMEN:</a>
        <ul><TMPL_LOOP PERSON>
          <li><a href="#<TMPL_VAR ANKER>"><TMPL_VAR KURZNAME></a></li></TMPL_LOOP>
        </ul>
      </div>
      <ul id="personen_long">
        <TMPL_LOOP PERSON>
        <li>
          <a name="<TMPL_VAR ANKER>" href="#top">Nach Oben</a>
          <ul>
            <li>
              <div class="p_typ" >Name:</div>
              <div class="p_txt"><TMPL_VAR nachname></div>
            </li>
            <li>
              <div class="p_typ" >Vorname:</div>
              <div class="p_txt"><TMPL_VAR vorname></div>
            </li>
            <li>
              <div class="p_typ" >Wohnort:</div>
              <div class="p_txt"><TMPL_VAR address></div>
            </li>
            <li>
              <div class="p_typ">E-Mail:</div>
              <div class="p_txt"><TMPL_VAR email></div>
            </li>
            <li>
              <div class="p_typ" >Homepage:</div>
              <div class="p_txt"><TMPL_VAR website></div>
            </li>
            <li>
              <div class="p_typ" >Zur Person:</div>
              <div class="p_txt"><TMPL_VAR person></div>
            </li>
            <li>
              <div class="p_typ" >Dienstzeit:</div>
              <div class="p_txt"><TMPL_VAR dienstzeit></div>
            </li>
            <li>
              <div class="p_typ" >Dienstgrad:</div>
              <div class="p_txt"><TMPL_VAR dienstgrad></div>
            </li>
            <li>
              <div class="p_typ" >Dienststellung:</div>
              <div class="p_txt"><TMPL_VAR dienststellung></div>
            </li>
            <li>
              <div class="p_typ" >Einheit/Schiff:</div>
              <div class="p_txt"><TMPL_VAR einheit></div>
            </li>
            <li>
              <div class="p_typ" >Schiff - Bordnummer:</div>
              <div class="p_txt"><TMPL_VAR nummer></div>
            </li>
            <li>
              <div class="p_typ" >Schiff - Projekt:</div>
              <div class="p_txt"><TMPL_VAR typ></div>
            </li>
          </ul>
        </li></TMPL_LOOP>
      </ul>
      <div id="document_bottom">
        <a class="link" href="<TMPL_VAR ACTION_INPUT>" title="Person Eingeben...">Person Eingeben...</a>
      </div>
      &nbsp;
    </div></div>
  </body>
</html>

#!/usr/bin/perl
use strict;
use warnings;
use HTML::Template::Compiled;
use CGI;
use CGI::Carp qw(fatalsToBrowser warningsToBrowser);
use PersonenDB;
use utf8;

# die benötigten Dateien
my $input_tmpl='input.tmpl';
my $show_tmpl='show.tmpl';
my $db_file='test.dat';

# Die Objkete erzeugen.
my $cgi  = CGI->new();
my $db   = PersonenDB->new($db_file);

# Ausgabe beginnen
print $cgi->header(-type=>"text/html", -charset=>"UTF-8");

# warungen in den Browser Ausgeben
warningsToBrowser(1);

# die gewünscht aktion bestimmen
my $action=lc($cgi->param('action') || '');
# wenn es keine bekannte Aktion ist, dann soll es 'show' sein
$action='show' unless(grep{$action eq $_}qw(show input send));

# Eingabemaske Zeigen
if($action eq 'input')
{
  zeige_maske($cgi,$db,$input_tmpl,{},'');
}
# Daten senden
elsif($action eq 'send')
{
  speicher_person($cgi,$db);
}
# Daten Anzeigen
else
{
  zeige_personen($cgi,$db,$show_tmpl);
}

# Eingabemaske generiegen und anzeigen
sub zeige_maske
{
  my $cgi=shift;
  my $db=shift;
  my $file=shift;
  my $user=shift || {};
  my $message=shift || '';
  my $tmpl = HTML::Template::Compiled->new(
    cache    => 0,
    filename => $file,
  );


  my %data;
  for my $key ($db->key_names())
  { $data{$key}=$user->{$key} || ''; }

  my @tmp=$db->typen();
  my @sel;
  for(1..@tmp)
  {
    my $v=shift(@tmp);
    push(@sel,{
        VALUE => $_,
        TITLE => $v->[0],
        TEXT  => $v->[1],
      });
  }

  $tmpl->param(
      MESSAGE     => $message,
      ACTION_SHOW => $cgi->script_name()."?action=show",
      ACTION_SEND => $cgi->script_name(),
      SELECT      => \@sel,
      %data,
    );

  print $tmpl->output();

  return 1;
}

# Daten lesen und Person speichern
sub speicher_person
{
  my $cgi=shift;
  my $db=shift;

  my %nutzer;
  for my $key ($db->key_names())
  { $nutzer{$key}=$cgi->param($key); }

  if($db->add(\%nutzer))
  { zeige_personen($cgi,$db,$show_tmpl); }
  else
  { zeige_maske($cgi,$db,$input_tmpl,\%nutzer,$db->error()); }

}


# Liste Generieren und anzeigen
sub zeige_personen
{
  my $cgi=shift;
  my $db=shift;
  my $file=shift;
  my $tmpl = HTML::Template::Compiled->new(
    cache    => 0,
    filename => $file,
  );

  my @typen=$db->typen();

  my $cnt=0;
  my @personen;
  for ($db->all())
  {
    my $person={%$_};

    $person->{ANKER}="anker$cnt";
    $person->{KURZNAME}="$person->{vorname} $person->{nachname}";

    if($person->{typ}<=0 || $person->{typ}>@typen)
    { $person->{typ}=''; }
    else
    {
      my $t=$typen[$person->{typ}-1];
      $person->{typ}="$t->[1] ($t->[0])";
    }

    push(@personen,$person);
    $cnt++;
  }

  $tmpl->param(
      ACTION_INPUT => $cgi->script_name()."?action=input",
      PERSON       => \@personen,
    );

  print $tmpl->output();
}